// Exemplo de arquivo de descricao de cena para POV-ray
// Fabio Massanori Sendo
// 02 Junho 2001


background{ color rgb < 1, 1, 1> }

#include "colors.inc"

camera {
    location <0,1.4,5>
    look_at <0,0,0>
  }

light_source { <10, 7, 7> color White }

#declare tinta_Azul = 
  texture {
    pigment { color rgb < 0, 0, 1 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }

#declare tinta_Verde = 
  texture {
    pigment { color rgb < 0, 1, 0 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }

#declare tinta_Vermelho = 
  texture {
    pigment { color rgb < 1, 0, 0 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }



// Os tres cilindros e somente para mostrar os eixos das coordenada
#declare cilindroX = 
  cylinder {
    < -3, 0, 0 >,
    < 3, 0, 0 >,
    0.01
    texture { tinta_Vermelho }
  }

#declare cilindroY = 
  cylinder {
    < 0,-3, 0 >,
    < 0, 3, 0 >,
    0.01
    texture { tinta_Azul }
  }

#declare cilindroZ = 
  cylinder {
    < 0, 0, -3 >,
    < 0, 0, 3 >,
    0.01
    texture { tinta_Verde}
  }

#declare cor_cristal = <0, 0 ,1.0>
#declare cristal = 
  texture {
    finish { 
	ambient 0.1
	diffuse 0.1 
	reflection 0.25
	specular 1 
	roughness 0.001
 	}
        pigment { color cor_cristal filter 1 }
  }

#declare cor_ouro = <1,0.8,0.5>
#declare ouro = 
  texture {
    finish { 
	ambient 0.05
	diffuse 0.05
	reflection cor_ouro
	specular 0.20
	roughness 0.05
 	}
        pigment { rgb cor_ouro  }
  }



#declare toroide_cristal =
    torus{ 1.5, 0.15  
	texture { cristal}
  }

#declare toroide_ouro =
    torus{ 1.5, 0.15   
	texture { ouro }
  }

#declare haste =
    torus{ 0.25, 0.125   
	texture { ouro }
	rotate 90*x
  }

#declare copa =
union
{
     // somente para mostrar os eixos cartesianos
     //object { cilindroX  }   // eixo X (Red)
     //object { cilindroY  }   // eixo Y (Blue)
     //object { cilindroZ  }   // eixo Z (Green)
     
     	object { toroide_ouro    translate <0, 1.50 ,0> scale <1.00,1,1.00>}
	object { toroide_cristal 
                 translate <0, 1.25 ,0> 
                 scale <0.98,1,0.98>
                 hollow interior{ior 1.5}}
	object { toroide_ouro    translate <0, 1.00 ,0> scale <0.93,1,0.93>}
	object { toroide_cristal 
                 translate <0, 0.75 ,0>
                 scale <0.87,1,0.87>
		 hollow interior{ior 1.5}}
	object { toroide_ouro    translate <0, 0.50 ,0> scale <0.75,1,0.75>}
	object { toroide_cristal 
                 translate <0, 0.25 ,0> 
                 scale <0.60,1,0.60>
		 hollow interior{ior 1.5}}
	object { toroide_ouro    translate <0, 0.00 ,0> scale <0.40,1,0.40>} 
   	object { haste   translate <0, -0.5  ,0> }
	object { haste   scale <1.25,1.25,1.25> 
			 translate <0, -0.85 ,0> 
                         rotate  45*y } 	
        object { haste   translate <0, -1.2  ,0> } 
	object { haste   scale <1.25,1.25,1.25>  
			 translate <0, -1.55 ,0> 
                         rotate -45*y }
	object { haste   translate <0, -1.9  ,0> }   
	
	difference{
	sphere {
    		< 0, -5.25, 0 >, 3 
    		texture { ouro}
  	       }
	sphere {
    		< 0, -6.7, 0 >, 4.3
    		texture { ouro}
  	       }
	
  	}
		 

}


union{ 
	object{ copa scale <1,0.65,1>}
	plane { y, -1.7  
		pigment { checker color Red, color Green}
		}
}