// Exercício de criação de cena - POV-Ray
// Criado em 26 de Maio de 2001 - Alan Keler Baldo - ra007850

#include "colors.inc"
#include "woods.inc"
#include "metals.inc"

//cor de fundo
background{ color rgb < 0.9, 0.9 , 0.9 > }


//fontes de luz
light_source {
  < 5.00, 25.00, 6.00 >
  color rgb < 1.0, 1.0, 1.0 >
}

//definicao da camera
camera {
  location  <  0.00, 25.00, 0.00 >
  right     < -1.00, 0.00, 0.00 >
  up        <  0.00, 0.00, 0.90 >
  sky       <  0.00, 0.00, 1.00 >
  look_at   <  0.00, 0.00, 0.00 >
} 

//declaracoes dos objetos
#declare metal = T_Chrome_3A

#declare madeira = T_Wood1

#declare eixox =
object  {
  cylinder {
    <-10.0, 0.0, 0.0>,
    <+10.0, 0.0, 0.0>,
    0.05
    texture { metal }
  }
}

#declare eixoy =
object  {
  cylinder {
    <0.0, -10.0, 0.0>,
    <0.0, +10.0, 0.0>,
    0.05
    texture { metal }
  }
}

#declare eixoz =
object  {
  cylinder {
    <0.0, 0.0, -10.0>,
    <0.0, 0.0, +10.0>,
    0.05
    texture { metal }
  }
}


#declare asa =
difference {
   intersection {
     box {
       < -2.00, -2.00, -0.14 >,
       < +2.00, +2.00, +0.14 >
       texture { metal }
     }
   cylinder {
     <-2.0, -2.0, -0.15>,
     <-2.0, -2.0, +0.15>,
     4.0
     texture { metal }
   }
 }
 union {
   cylinder {
     <-2.0, -1.0, -0.16>,
     <-2.0, -1.0, +0.16>,
     1.0
     texture { metal }
   }
   cylinder {
     <-2.0, +1.0, -0.16>,
     <-2.0, +1.0, +0.16>,
     1.0
     texture { metal }
   }
 }
}

#declare corpo=
difference {
   union {
      cylinder {
        <+4.0, 0.0, +1.0>,
        <-6.0, 0.0, +1.0>,
        1.0
        texture { metal }
      }
      sphere {
       < 0.0, 0.0, 0.0 >, 1.00
       scale <2.0, 1.0, 1.0>
       translate <+4.0, 0.0, 1.0>
       texture { metal }
     }
     object {
        asa
        rotate -90*x
        rotate 180*y
        rotate 180*z
        translate <-10.0,0.0,+6.0>
        scale <0.5,0.5,0.5>
     }
   }
   union {
      sphere {
       < 0.0, 0.0, 0.0 >, 1.0
       translate <+1.0, 0.0, 1.8>
       texture { metal }
     }
      sphere {
       < 0.0, 0.0, 0.0 >, 1.0
       translate <-0.5, 0.0, 1.8>
       texture { metal }
     }
      sphere {
       < 0.0, 0.0, 0.0 >, 1.0
       translate <-2.0, 0.0, 1.8>
       texture { metal }
     }
   }
}

#declare remo=
object {
  union {
     box {
       < -0.1, +0.0, -0.04 >,
       < +0.1, +1.8, +0.04 >
       texture { madeira }
     }
     cylinder {
       <0.0, 0.0, -0.04>,
       <0.0, 0.0, +0.04>,
       0.2
       texture { madeira }
       translate <0.0, +1.8, 0.0>
     }
  }
  rotate -75*y
  rotate -15*x
}

#declare aviao =
union {
   object {
   	corpo
   }

   object {
      remo
      translate <1.0, 0.3, 1.0>
   }
   object {
      remo
      translate <-0.5, 0.3, 1.0>
   }
   object {
      remo
      translate <-2.0, 0.3, 1.0>
   }

   object {
      remo
      rotate 180*x
      rotate 180*y
      translate <1.0, -0.3, 1.0>
   }
   object {
      remo
      rotate 180*x
      rotate 180*y
      translate <-0.5, -0.3, 1.0>
   }
   object {
      remo
      rotate 180*x
      rotate 180*y
      translate <-2.0, -0.3, 1.0>
   }

   object {
   	asa
   	translate <-5.0,+3.0,+1.0>
   }
   object {
   	asa
   	rotate 180*x
   	translate <-5.0,-3.0,+1.0>
   }
   object {
   	asa
   	translate <+3.5,+4.0,+2.0>
   	scale <0.5,0.5,0.5>
   }
   object {
   	asa
   	rotate 180*x
   	translate <+3.5,-4.0,+2.0>
   	scale <0.5,0.5,0.5>
   }
}

//Exibicao de objetos

/*eixox
eixoy
eixoz*/

object {
	aviao
	scale <0.5,0.5,0.5>
	rotate -15*x
	translate <0.0, 0.0, 8.0>
}

object {
	aviao
	scale <0.5,0.5,0.5>
	rotate 102.5*z
	rotate -15*x
	translate <6.0, 0.0, 6.0>
}

object {
	aviao
	scale <0.5,0.5,0.5>
	rotate -90*x
	translate <0.0, 0.0, 4.0>
}

object {
	aviao
	scale <1.6,1.6,1.6>
	rotate 38*z
	rotate -25*x
	translate <1.5, 0.0, -6.0>
}