// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2010-03-04 15:44:01 by stolfi

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico = 
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca = 
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho = 
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro = 
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }


#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

// ======================================================================
// DESCRIÇÃO DA CENA 

#macro interpola_1 (tt, tt0, vv0, tt1, vv1)
  #local p = (tt - tt0) / (tt1 - tt0);
  vv0 + p * (vv1 - vv0)
#end

#macro gera_segmento_1 (n, p0, r0, p1, r1)
  union {
    #declare i = 0;
      
      #while (i < n)
      
        #local p = interpola_1 (i, 0, p0, n-1, p1); 
        
        sphere {
          p, interpola_1(i, 0, r0, n - 1, r1)
          texture{ tx_plastico }
        }
        
        #declare i = i + 1;
        
      #end
  }
#end

#macro interpola_3 (tt, t0, t1, a, b, c, d)
  #local ab = interpola_1(tt, t0, a, t1, b);
  #local bc = interpola_1(tt, t0, b, t1, c);
  #local cd = interpola_1(tt, t0, c, t1, d);
  
  #local abc = interpola_1(tt, t0, ab, t1, bc);
  #local bcd = interpola_1(tt, t0, bc, t1, cd);
  #local abcd = interpola_1(tt, t0, abc, t1, bcd);
  abcd
#end

#macro gera_segmento_3(n, pa, ra, pb, rb, pc, rc, pd, rd)
  union {
   #declare i = 0;
   
    #while (i < n) 
      #local p = interpola_3(i, 0, n - 1, pa, pb, pc, pd);
      
      sphere {
          p, interpola_3(i, 0, n - 1, ra, rb, rc, rd)
          texture{ tx_plastico }
        }
      #declare i = i + 1;
      
    #end
  }
#end

#include "eixos.inc"

// Aqui está a cena, finalmente:

// object{ gera_segmento_1(10, <0.00, 0.00, 0.00>, 0, <0.00, 5.00, 0.00>, 2) }
object{ gera_segmento_3(100, <0.00, 0.00, 0.00>, 1, <0.00, 1.50, 4.50>, 0.9, <0.00, 3, 0.50>, 0.7, <0.00, 4.50, 2.5>, 0.5) }
object{ eixos(3.00) }


#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 1.00 >;
#declare raio_cena = 10.0;
#declare dir_camera = < 14.00, 7.00, 8.00 >;
#declare dist_camera = 40.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)