// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2010-03-04 15:44:01 by stolfi

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico = 
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca = 
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho = 
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro = 
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }


#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

// ======================================================================
// DESCRIÇÃO DA CENA 

#macro enlace (p, q, tp, rr)
  union {
    cylinder {
      p,
      q,
      0.1
      texture{ tx_vidro }
    }
    #if (tp < 8)
      sphere {
        rr * p + (1 - rr) * q, 0.15
        texture{ tx_fosca }
      }
    #end
  }
#end

#macro rede (n, m)

  #declare sizes = array[n];
  #declare positions = array[n];
  #declare roleta = seed(0);

  #declare i = 0;
  
  #while (i < n)
    
    #declare sizes[i] = 0.2 + 0.2 * rand(roleta);
    #declare positions[i] = <8 * rand(roleta), 8 * rand(roleta), 8 * rand(roleta)>;
    
    #declare i = i + 1;
  #end

  union {
    #declare i = 0;
    
    #while (i < n)
      sphere {
        < 0.00, 0.00, 0.00 > + positions[i], sizes[i]
        texture{ tx_plastico }
      }
      
      #declare i = i + 1;
    #end
    
    #declare i = 0;
    
    #while (i < m)
      #declare p = int(n * rand(roleta));
      #declare q = int(n * rand(roleta));
      #declare tp = int(10 * rand(roleta));
      #declare rr = rand(roleta);
      object{ enlace(positions[p], positions[q], tp, rr) }
      
      #declare i = i + 1;
    #end
  }

#end

#include "eixos.inc"

// Aqui está a cena, finalmente:

object{ rede(100, 50) }
object{ eixos(3.00) }


#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 1.00 >;
#declare raio_cena = 10.0;
#declare dir_camera = < 14.00, 7.00, 8.00 >;
#declare dist_camera = 40.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)