// Last edited on 2017-05-07 20:06:16 by stolfilocal
// Processed by remove-cam-lights

background{ color rgb < 1.00, 0.60, 0.85 > }

#declare tx_plastico =
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca =
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_cinza =
  texture{
    pigment{ color rgb < 0.75, 0.75, 0.75 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

#declare raio = 0.500;
#declare Ra = 0.750;

#macro enlace(p,q,tr,rr)
    union {
        cylinder{ p, q, 0.2  texture{tx_cinza}}
        #if (tr = 1)
            #declare c = (1-rr)*p+rr*q;
            box{ <+0.3, +0.3, +0.3> + c, <-0.3, -0.3, -0.3> + c  texture{tx_plastico}}
        #end
    }
#end

#declare tamr = 20;

#macro rede(N,M)
    #declare nos_pos = array[N]
    #declare nos_tam = array[N]

    union {
        #declare roleta = seed(417);
        #declare i = 0;
        #while (i<N)
            #declare nos_pos[i] = <tamr*rand(roleta), tamr*rand(roleta), tamr*rand(roleta)>;
            #declare nos_tam[i] = 0.4 + 0.1*rand(roleta);
            sphere{ nos_pos[i], nos_tam[i]  texture{tx_fosca}}
            #declare i = i+1;
        #end
        #declare i = 0;
        #while (i<M)
            #declare p = int((N-1)*rand(roleta));
            #declare q = int((N-2)*rand(roleta));
            #if (p <= q)
                #declare q = q+1;
            #end
            object{enlace(nos_pos[p],nos_pos[q],int(2*rand(roleta)),rand(roleta))}
            #declare i = i+1;
        #end

    }

#end

#declare chao =
    box{ <-20,-20,-1>, <+20,+20,0> }

#include "eixos.inc"

union{
    object { eixos(7.00) }
    object {chao    texture{tx_xadrez}}
    object { rede(100,50)}
}

#include "camlight.inc"
#declare centro_cena = 0.5*tamr * < 1, 1, 1 >;
#declare raio_cena = 1.00*tamr;
#declare dir_camera = < 14.00, 7.00, 4.00 >;
#declare dist_camera = 8*raio_cena;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)