// Last edited on 2017-05-07 20:06:06 by stolfilocal
// Processed by remove-cam-lights

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico1 =
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_plastico2 =
  texture{
    pigment{ color rgb < 1.00, 0.10, 0.10 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca =
  texture{
    pigment{ color rgb < 1.00, 1.00, 1.00 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho =
  texture{
    pigment{ color rgb < 1.00, 0.25, 0.50 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro =
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }

#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

#macro enlace(p,q,tp,rp)
    #if(tp)
        #declare pos1 = (1-rp)*p + rp*q;
        union{
            cylinder{p, q, 0.08 texture{tx_fosca}}
            sphere{pos1, 0.3 texture{tx_plastico2}} //pacote

        }
    #else
        cylinder{p, q, 0.08 texture{tx_fosca}}
    #end
#end

#declare tamr = 20;

#macro rede(n, m)
    #declare pos = array[n]
    #declare tam = array[n]
    #declare aleat = seed(417);

    #declare i = 0;
    #while(i < n)
        #declare pos[i] = <tamr*rand(aleat),tamr*rand(aleat), tamr*rand(aleat)>;
        #declare tam[i] = rand(aleat);
        #declare i = i + 1;
    #end

    union{
        #declare i = 0;
        #while(i < n)
            sphere{pos[i], tam[i] texture{tx_vidro}}
            #declare i = i + 1;
        #end

        #declare i = 0;
        #while(i < m)
            #declare j = int((n-2)*rand(aleat));
            #declare k = int((n-2)*rand(aleat));
            #if(j = k)
                #declare k = k + 1;
            #end
            object{enlace(pos[j], pos[k],(rand(aleat)< 0.5), rand(aleat))}
            #declare i = i + 1;
        #end

    }
#end

#include "eixos.inc"

union{
    object{rede(100, 50)}

}
#include "camlight.inc"
#declare centro_cena = 0.5*tamr * < 1, 1, 1 >;
#declare raio_cena = 1.00*tamr;
#declare dir_camera = < 14.00, 7.00, 4.00 >;
#declare dist_camera = 8*raio_cena;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)