// Last edited on 2017-05-07 20:07:02 by stolfilocal
// Processed by remove-cam-lights

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico =
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_plastico_2 =
  texture{
    pigment{ color rgb < 0.70, 0.25, 0.75 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca =
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho =
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro =
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }

#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

#declare i = 0;
#declare j = 0;
#declare n = 0;
#declare k = 0;
#declare l = 0;

#declare tamr = 100;

#macro nos(n)

        #declare matriz_posicao = array[n]
        #declare matriz_tamanho = array[n]

        #declare roleta = seed(666);

        union{
                #while(i < n)
                        #declare matriz_posicao[i] = <tamr * rand(roleta), tamr * rand(roleta), tamr * rand(roleta)>;
                        #declare matriz_tamanho[i] = 4 * rand(roleta);
                        sphere{ matriz_posicao[i], matriz_tamanho[i] texture{tx_fosca} }
                        #declare i = i + 1;
                #end
                #while(j < n)
                        #declare k = int(n * rand(roleta));
                        #declare l = int((n - 1) * rand(roleta));
                        #if(l >= k)
                                #declare l = l + 1;
                        #end
                        object{ enlace(matriz_posicao[k], matriz_posicao[l], int(2 * rand(roleta)), rand(roleta)) }
                        #declare j = j + 1;
                #end
        }

#end

#macro enlace(p, q, tp, rr)
        #if(tp = 0)
                cylinder{ p, q, 0.25 texture{tx_plastico} }
        #else
                union{
                cylinder{ p, q, 0.25 texture{tx_plastico}}
                box{ <0, 0, 0>, <5, 5, 5> translate((1 - rr) * p + rr * q) texture{tx_plastico_2} }
                }
        #end
#end

#include "eixos.inc"

object{ nos(100) }

#include "camlight.inc"
#declare centro_cena = 0.5*tamr * < 1, 1, 1 >;
#declare raio_cena = 1.00*tamr;
#declare dir_camera = < 14.00, 7.00, 4.00 >;
#declare dist_camera = 8*raio_cena;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)