// Exemplo de arquivo de descricao de cena para POV-ray
// Nome: Flávio Marcos Helder Moura     RA:104947

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico = 
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }
  
#declare tx_plastico_2 = 
  texture{
    pigment{ color rgb < 0.70, 0.25, 0.75 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }  

#declare tx_fosca = 
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho = 
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro = 
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }


#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

// ======================================================================
// DESCRIÇÃO DA CENA 

#declare i = 0;
#declare j = 0;

#macro soldado(tipo, raio, tx1, tx2, tx3, tx4, tx5, tx6, tx7, tx8)
	union{
		box{ <0, 0, 30>, <-20, 40, 90> texture {tx1}}
		
		#if(tipo = 0)                      
			cone{ <-10, 20, 100>, 10, <-10, 20, 115>, 0 texture {tx2}}
		#else
			cone{ <-10, 20, 100>, 10, <-10, 20, 145>, 0 texture {tx8}}	
		#end
		cylinder{ <-10, 40, 80>, <-10, 55, 55>, 5 texture {tx3}}
		cylinder{ <-10, 0, 80>, <-10, -15, 55>, 5 texture {tx4}}
		cylinder{ <-10, 10, 30>, <-10, 10, 0>, 5 texture {tx5}}
		cylinder{ <-10, 30, 30>, <-10, 30, 0>, 5 texture {tx6}}
		sphere{ <-10, 20, 95>, raio texture {tx7}}
	}
#end

#macro pelotao(linha, coluna)
	union{
		#while(i < linha)
			#while(j < coluna)
				#if((j = 0 & i = 0) | (j = 0 & i = linha - 1) | (j = coluna - 1 & i = 0) | (j = coluna - 1 & i = linha - 1) | (j = int(coluna / 2) & i = int(linha / 2)))
					object{ soldado(1, 10, tx_fosca, tx_plastico, tx_fosca, tx_fosca, tx_fosca, tx_fosca, tx_vidro, tx_plastico_2) translate<70 * i, 70 * j, 0> }
				#else
					object{ soldado(0, 10, tx_fosca, tx_plastico, tx_fosca, tx_fosca, tx_fosca, tx_fosca, tx_vidro, tx_plastico_2) translate<70 * i, 70 * j, 0> }
				#end
				#declare j = j + 1;
			#end
			#declare j = 0;
			#declare i = i + 1;
		#end
	}
#end

#include "eixos.inc"

// Aqui está a cena, finalmente:

object{ eixos(100.00) }
object{ pelotao(5, 5) }

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 1.00 >;
#declare raio_cena = 470.0;
#declare dir_camera = < 14.00, 7.00, 4.00 >;
#declare dist_camera = 900.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)