// Last edited on 2017-05-04 04:38:41 by stolfilocal
// Processed by remove-cam-lights

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico =
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca =
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho =
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro =
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }

#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

#declare cabeca =
  sphere{ < 0,0,0 >, 6
  texture{ tx_fosca }
}

#declare tronco =
       cone {
            <0,0,0>,8,
            <0,0,22>,4
            texture{ tx_fosca }
        }

#declare pernas =
   cone {
        <0,0,0>,5,
        <0,0,20>,8
        texture{ tx_fosca }
    }

#declare ombros =
  cylinder{
    < -13, 0, 0 >,
    < 13, 0, 0 >,
    2
    texture{ tx_fosca }
  }

#declare chapeu =
   box {
     <-3,-7,-2>,
     <3,7,2>
    texture{ tx_fosca }
   }

#declare chao =
  box{ <-20,-20,-1>, <-20,+20,0> }

#macro soldado( sargento, tx )
union{

  object{ pernas  translate < 0,0,0 > texture{tx} }
  object{ tronco  translate < 0,0,20 > texture{tx} }
  object{ cabeca  translate < 0,0,40 > texture{tx} }
  object{ ombros  translate < 0,0,32 > texture{tx} }
  #if (sargento)
    object {chapeu translate < 0,0,44 > texture{tx_xadrez}}
  #end

}

#end

#macro pelotao (linhas,colunas)
    union{
        #declare i = 0;

        #while (i<linhas)

           #declare j = 0;
           #while (j<colunas)
               #if ((i=0 & (j=0 | j=colunas-1)) |
                   (i=linhas-1 & (j=0 | j=colunas-1)) | (i=int(linhas/2) & j=int(colunas/2)))
                  object{ soldado(1,tx_vidro) translate <30*i,30*j,0> }
               #else
                  object{ soldado(0,tx_vidro) translate <30*i,30*j,0> }
               #end
               #declare j = j+1;
           #end

           #declare i = i+1;
        #end
    }
#end

#include "eixos.inc"

object{ eixos(3.00) }

object { pelotao(9,7) }

#include "camlight.inc"
#declare centro_cena = < 150.00, 75.00, 20.00 >;
#declare raio_cena = 200.0;
#declare dir_camera = < 14.00, 7.00, 6.00 >;
#declare dist_camera = 320.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)