// Last edited on DATE TIME by USER
// Processed by remove-cam-lights

background{ color rgb < 0.66, 0.40, 0.15 > }

#declare tx_plastico =
  texture{
    pigment{ color rgb < 0.20, 0.70, 0.10 > }
    finish{ diffuse 0.7 ambient 0.2 specular 0.6 roughness 0.105 }
  }

#declare tx_fosca =
  texture{
    pigment{ color rgb < 0.50, 0.30, 0.25 > }
    finish{ diffuse 0.49 ambient 0.2 }
  }

#declare tx_espelho =
  texture{
    pigment{ color rgb < 0.70, 0.15, 0.90 > }
    finish{ diffuse 0.3 reflection 0.7*< 1.20, 0.75, 0.10 > ambient 0.2 }
  }

#declare tx_vidro =
  texture{
    pigment{ color rgb < 0.25, 0.45, 0.30 > filter 0.60 }
    finish{ diffuse 0.03 reflection 0.35 ambient 0.02 specular 0.15 roughness 0.005 }
  }

#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.90, 0.92, 0.90 >, color rgb < 0.10, 0.47, 0.08 > }
    finish{ diffuse 0.9 ambient 0.5 }
    scale 2.0
  }

#declare raio = 2.500;

#declare bolinha =
  sphere{ < 1,0,0 >, 0.60 }

#declare bolota =
  sphere{ < 0,1,0 >, 1.50 }

#declare bola =
  sphere{
    < 0.00, 0.00, 1.00 >, raio
    texture{ tx_plastico }
  }

#declare pino =
  cylinder{
    < -2.30, +2.40, -1.00 >,
    < +2.70, -1.70, +1.00 >,
    0.55
    texture{ tx_fosca }
  }

#declare furo =
  cylinder{
    < -1.90, -2.80, -2.00 >,
    < +1.20, +2.30, +2.00 >,
    0.65*raio
    texture{ tx_fosca }
  }

#declare chao =
  box{ <-20,-30,-1>, <+30,+20,0> }

#include "eixos.inc"

union{
  object{ eixos(3.00) }

  object{ chao  translate < 0,0,-5 > texture{ tx_xadrez } }
  object{ bolota  translate < -2,+1,+3 > texture{ tx_espelho } }
  object{ bolinha translate < +5,+4,+2 > texture{ tx_vidro } interior { ior 1.01 } }

  difference{
    union{
      object{ bola }
      object{ pino }
    }
    object{ furo }
  }
}

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 1.00 >;
#declare raio_cena = 6.0;
#declare dir_camera = < 14.00, 7.00, 4.00 >;
#declare dist_camera = 16.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)