// Last edited on DATE TIME by USER
// Processed by remove-cam-lights

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico =
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca =
  texture{
    pigment{ color rgb < 0.75, 0.75, 0.75 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_vidro =
  texture{
    pigment{ color rgb < 0.3, 0.4, 0.55 > filter 0.70 }
    finish{ diffuse 0.03 reflection 1 ambient 0.1 specular 0.25 }
  }

#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.30, 0.60, 0.30 >, color rgb < 0.60 ,1.0, 0.60 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

#declare raio = 2.000;

#declare chao =
  box{ <-20,-20,-1>, <+20,+20,0> }

#macro comodo(n,m,b)

#declare cubo =
  box{
    <0,0,0>,
    <n,n,n>
    texture{ tx_fosca }
  }

  #declare janela =
  box{
    <0,0,0>,
    <0.25,n/2,n/2>
  }

  #declare teto =
  box{
    <0,0,0>,
    <n*1.2,n*1.2,n/5>
    texture{ tx_fosca }
  }

  #declare ponta =
  cone{
   <0,0,0>, n
   <0,0,n>, 0
   texture{ tx_vidro }
  }

 union{
  difference{
        object{ cubo translate<m,0,0>}
        object{ janela translate<m+n-0.05,n/4,n/10>}
  }
  object{teto translate<(-0.1*n)+m,-0.1*n, n>}
  #if (b=1)
    object{ponta translate<m+(n/2),n/2,1.2*n>}
  #end
 }
#end

#macro torre(n)

 #declare pino =
  cylinder{
    < 0,0,0 >,
    < 0,0,n >,
    n/5
    texture{ tx_vidro }
  }

 #declare ponta =
  cone{
   <0,0,0>, (n/5)*1.2
   <0,0,n/4>, 0
   texture{ tx_vidro }
  }

 union{
  object{pino}
  object{ponta translate<0,0,n>}
 }

#end

#declare roleta = seed(4);

#macro castelo(p,n,m)

 #local r1 = rand(roleta)*0.7;
 #local r2 = rand(roleta)*0.7;

 #if (p < 3)
  union{
     object{comodo(n,m,0)}
     object{castelo(p+1, r1*n, m+n/3) translate<0,0.05*n,1.2*n>}
     object{castelo(p+1, r2*n, m+n/3) translate<0,0.7*n,1.2*n>}
  }
 #else
   object{comodo(n,m,1) }
 #end

#end

#include "eixos.inc"

union{
  object{ eixos(3.00) }

  object{ chao  translate < 1,1,-4 > texture{ tx_xadrez } }
  object{ castelo(0,1.5,0) rotate<0,0,30>}
  object{torre(1) translate<1.5,0,0> rotate<0,0,15>}
  object{torre(1) translate<2.3,0,0> rotate<0,0,90>}

}

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 1.00 >;
#declare raio_cena = 6.0;
#declare dir_camera = < 7.00, 14.00, 7.00 >;
#declare dist_camera = 16.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)