// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2010-03-04 15:44:01 by stolfi

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico = 
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca = 
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_fosca_vermelha = 
  texture{
    pigment{ color rgb < 1.00, 0.30, 0.30 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho = 
  texture{
    pigment{ color rgb < 1.00, 1.0, 1.0 > }
    finish{ diffuse 0.5 reflection 0.7*< 1.0, 1.0, 1.0 > ambient 0.7 }
  }

#declare tx_vidro = 
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }


#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

// ======================================================================
// DESCRIÇÃO DA CENA 

#declare raio = 2.000;

// Partes da cena:
#declare pe = 
  box {
    < -0.6, -0.4, -0.2 >,
    < +0.6, +0.4, +0.2 >
    texture{ tx_fosca }
  }

#declare perna =
  cylinder {
    < 0.00, -0.20, -1.5 >,
    < 0.00, +0.20, +1.5 >,
    0.2
    texture{ tx_fosca }
  }

#declare corpo =
  cylinder {
    < +2.20, 0.00, 0 >,
    < -2.40, 0.00, 0 >,
    1.0
    texture{ tx_fosca }
  }

#declare pescoco =
  cylinder {
    < +0.0, -0.0, 0 >,
    < +0.3, +0.3, 1 >,
    0.2
    texture{ tx_fosca }
  }

#declare cabeca =
  union {
    sphere {
      < 0.0, 0.0, 0.0 >, 0.8
      texture{ tx_fosca }
    }
    cone {
      < 0.0, 0.0, 0.0 >, 0.4
      < 0.5, -0.8, 1.3 >, 0.0
      texture{ tx_fosca_vermelha }
    }
    cone {
      < 0.0, 0.0, 0.0 >, 0.4
      < 0.5, +0.8, 1.3 >, 0.0
      texture{ tx_fosca_vermelha }
    }
    sphere {
      < 0.7, 0.3, 0.3 >, 0.12
      texture{ tx_vidro }
    }
    sphere {
      < 0.7, -0.3, 0.3 >, 0.12
      texture{ tx_vidro }
    }
  }

#declare chao = 
  box{ <-20,-20,-1>, <+20,+20,0> }

#include "eixos.inc"

// Aqui está a cena, finalmente:

union{
  object{ eixos(3.00) }

  object{ chao  translate < 0,0,0 > texture{ tx_xadrez } }

  union {
    object{ pe  translate < -2,-1,+0.2 > texture{ tx_fosca } }
    object{ pe  translate < -2,+1,+0.2 > texture{ tx_fosca } }
    object{ pe  translate < +2,+1,+0.2 > texture{ tx_fosca } }
    object{ pe  translate < +2,-1,+0.2 > texture{ tx_fosca } }

    object{ perna scale <1.0, +1.0, 1.0> translate < -2.2,-0.8,+1.2 > texture{ tx_vidro } }
    object{ perna scale <1.0, +1.0, 1.0> translate < +1.8,-0.8,+1.2 > texture{ tx_vidro } }
    object{ perna scale <1.0, -1.0, 1.0> translate < -2.2,+0.8,+1.2 > texture{ tx_vidro } }
    object{ perna scale <1.0, -1.0, 1.0> translate < +1.8,+0.8,+1.2 > texture{ tx_vidro } }

    object{ corpo translate < 0,0,+3.2 > texture{ tx_vidro } }

    object{ pescoco scale <1.0, +1.0, 1.0> translate < +1.8, +0.4, +4.1 > texture{ tx_vidro } }
    object{ pescoco scale <1.0, -1.0, 1.0> translate < +1.8, -0.4, +4.1 > texture{ tx_vidro } }

    object{ cabeca scale <1.0, 1.0, 1.0> translate < +2.1, +0.8, +5.7 > texture{ tx_vidro } }
    object{ cabeca scale <1.0, 1.0, 1.0> translate < +2.1, -0.8, +5.7 > texture{ tx_vidro } }
  }
}

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 3.00 >;
#declare raio_cena = 7.0;
#declare dir_camera = < 14.00, 7.00, 4.00 >;
#declare dist_camera = 24.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)