// Exemplo de arquivo de descricao de cena para POV-ray

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 1.00, 1.00, 1.00 > }

#declare tx_plastico = 
  texture{
    pigment{ color rgb < 0.71, 0.45, 0.19 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_plastico2 = 
  texture{
    pigment{ color rgb < 0.99, 0.0, 0.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }
#declare tx_xadrez2 =
  texture{
    pigment{ checker color rgb < 0.60, 0.32, 0.10 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

#declare tx_vidro = 
  texture{
    pigment{ color rgb < 0.9, 0.55, 0.00 > filter 0.90 }
    finish{ diffuse 0.05 ambient 0.00 }
  }

#declare tx_vidro2 = 
  texture{
    pigment{ color rgb < 0.45, 0.75, 0.50 > filter 0.90 }
    finish{ diffuse 0.05 ambient 0.00 }
  }


// ======================================================================
// DECLARAÇÃO DE OBJETOS

#declare raio = 2.000;

// Partes da cena:

#include "eixos.inc"
#include "retalho.inc"

#declare chao = 
  box{ <-100,-100,-1>, <+100,+100,0> }
  
#declare phi = ( sqrt(5) + 1 ) / 2;

#declare ponto =
  sphere{ <0,0,0>, 0.5 }

// ======================================================================
// DESCRIÇÃO DE MACROS

#macro interpola(t0,v0,t1,v1,tt)
 #local ss= (tt-t0)/(t1-t0);
 #local rr= 1-ss;
 (rr*v0 + ss*v1)
#end

#macro interpola4(t0,v0,v1,v2,v3,t1,tt)
 #local v01=interpola(t0,v0,t1,v1,tt);
 #local v12=interpola(t0,v1,t1,v2,tt);
 #local v23=interpola(t0,v2,t1,v3,tt);
 #local v012=interpola(t0,v01,t1,v12,tt);
 #local v123=interpola(t0,v12,t1,v23,tt);
 #local v0123=interpola(t0,v012,t1,v123,tt);
 v0123
#end

/*#macro ponto_grafico(ponto_x,ponto_y)
  object{ ponto translate<ponto_x,ponto_y,0> }
#end*/

#macro ponto_grafico(ponto_x,ponto_y)
  object{ sphere { ponto_y, 0.5 } }
#end

#macro grafico(x0,y0,y1,y2,y3,x3,N)
  union{
    #local intervalo = (x3-x0)/N;
    #local x_atual = x0;
    #while(x_atual <= x3)
      #local y_atual=interpola4(x0,y0,y1,y2,y3,x3,x_atual);
      object{ ponto_grafico(x_atual,y_atual) }
      #local x_atual = x_atual + intervalo;
    #end //while
  }
#end



#macro graficos_emendados(v01,v02,v11,v12,v21,v22,v31,v32,N)
 #local ponto_uniao1=(v02+v11)/2;
 #local ponto_uniao2=(v12+v21)/2;
 #local ponto_uniao3=(v22+v31)/2;
 #local ponto_uniao4=(v32+v01)/2;
union{
  object { grafico(0,ponto_uniao4,v01,v02,ponto_uniao1,3,N) texture{tx_plastico} }
  object { grafico(3,ponto_uniao1,v11,v12,ponto_uniao2,6,N) texture{tx_plastico2} }
  object { grafico(6,ponto_uniao2,v21,v22,ponto_uniao3,9,N) texture{tx_plastico} }
  object { grafico(9,ponto_uniao3,v31,v32,ponto_uniao4,12,N) texture{tx_plastico2} }
}
#end

#macro retalho_emendado(p11,p12,p13,p14,p21,p22,p23,p24,p31,p32,p33,p34,q21,q22,q23,q24,q31,q32,q33,q34,q41,q42,q43,q44,raio,text1,text2)
 #local pq1 = (p31+q21)/2;
 #local pq2 = (p32+q22)/2;
 #local pq3 = (p33+q23)/2;
 #local pq4 = (p34+q24)/2;
union{
  object { retalho(p11,p12,p13,p14,p21,p22,p23,p24,p31,p32,p33,p34,pq1,pq2,pq3,pq4,raio,text1,text1) }
  object { retalho(pq1,pq2,pq3,pq4,q21,q22,q23,q24,q31,q32,q33,q34,q41,q42,q43,q44,raio,text2,text2) }
}
#end

// ======================================================================
// ANIMAÇÃO

// ======================================================================
// DESCRIÇÃO DA CENA 

union{
  object { chao translate < 0,0,-10 > texture{tx_xadrez} }
  //object { grafico(0,10,1,2,12,5,10) }
  object { graficos_emendados(<6,10,3>,<2,6,8>,<8,7,6>,<6,9,7>,<5,1,7>,<10,5,2>,<7,4,5>,<8,1,6>,100) translate<10,-3,0> }
  object { retalho_emendado(<1,10,-9>,<-1,-3,-8>,<10,6,9>,<-9,-10,1>,<9,10,-7>,<-8,4,-6>,<-6,7,-10>,<-5,9,0>,<3,-5,-10>,<-7,-9,2>,<7,-8,3>,<10,-8,3>,<-5,-5,-2>,<-9,8,-10>,<3,6,9>,<1,-4,-5>,<-6,8,3>,<-9,-3,1>,<9,2,3>,<-10,-9,-8>,<-7,5,3>,<2,3,8>,<-8,-5,5>,<-7,9,9>,0.01,tx_plastico,tx_plastico2) translate<-10,0,0> }

  object{ eixos(40) }

}


#include "camlight.inc"
#declare centro_cena = < 5.00, 5.00, 1.00 >;
#declare raio_cena = 32;
#declare dir_camera = < 0.00, 10.0, 6.00 >;
#declare dist_camera = 16.00;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)