// Last edited on DATE TIME by USER
// Processed by remove-cam-lights

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico =
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca =
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_branca =
  texture{
    pigment{ color rgb < 2, 2, 2> }
  }

#declare tx_preta =
  texture{
    pigment{ color rgb < 0, 0, 0> }
  }

#declare tx_orelha =
  texture{
    pigment{ color rgb < 0.80, 0.80, 0.8 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }
#declare tx_espelho =
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro =
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }

#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

#include "eixos.inc"

#declare raio_cabeca = 0.5;
#declare raio_olho = 0.2*raio_cabeca;

#macro cranio(xc,yc,zc)
        difference {
                sphere {
                        <xc,yc,zc> , raio_cabeca
                }
                box {
                        <xc,yc-raio_cabeca,zc-raio_cabeca>,
                        <xc+raio_cabeca,yc+raio_cabeca,zc+raio_cabeca>
                }
        }
#end
#macro orelha(xc,yc,zc)
        box {
                <xc,yc-raio_cabeca/2-0.1,zc+0.75*raio_cabeca>
                <xc,yc-raio_cabeca/2+0.1,zc+0.75*raio_cabeca+0.5>
                texture{tx_orelha}
        }
#end

#macro cabeca(xc,yc,zc)
union {
        cranio(xc,yc,zc)
        box {
                <xc,yc-raio_cabeca/2-0.1,zc+0.75*raio_cabeca>
                <xc,yc-raio_cabeca/2+0.1,zc+0.75*raio_cabeca+0.5>
                texture{tx_orelha}
        }
        box {
                <xc,yc+raio_cabeca/2-0.1,zc+0.75*raio_cabeca>
                <xc,yc+raio_cabeca/2+0.1,zc+0.75*raio_cabeca+0.5>
                texture{tx_orelha}
        }
        box {
                <xc+0.01,yc-raio_cabeca/2,zc>
                <xc+0.01,yc+raio_cabeca/2,zc-raio_cabeca/2>
                        texture{tx_preta}
        }
        box {
                <xc+0.02,yc-raio_cabeca/4,zc>
                <xc+0.02,yc-0.01,zc-raio_cabeca/4>
                        texture{tx_branca}
        }
        box {
                <xc+0.02,yc+0.01,zc>
                <xc+0.02,yc+raio_cabeca/4,zc-raio_cabeca/4>
                        texture{tx_branca}
        }
        sphere {
                <xc-raio_olho/2,yc-raio_cabeca/2,zc+raio_cabeca/2>
                raio_olho
                texture{tx_branca}
        }
        sphere {
                <xc-raio_olho/2,yc+raio_cabeca/2,zc+raio_cabeca/2>
                raio_olho
                texture{tx_branca}
        }
}
#end

#declare rjunta = 0.15;
#macro junta(xc,yc,zc)
        sphere {
                <xc,yc,zc>
                rjunta
        }
#end

#declare gpe = 0.15;
#declare hpe = 0.3;
#macro pe(xp,yp,zp,rot)
union {
        box {
              <xp-2*gpe,yp-2*
gpe,zp>
              <xp+2*gpe,yp+gpe,zp-hpe>
        }

        box {
              <xp-2*gpe,yp-gpe,zp-0.55*hpe>
              <xp+3*gpe,yp+gpe,zp-hpe>
        }
        translate<-xp,-yp+gpe,0>
        rotate<0,0,rot>
        translate<xp,yp-gpe,0>
}
#end

#declare lcorpo = 2.5*raio_cabeca;
#declare hcorpo = 2;
#macro corpo(xc,yc,zc)
union {
        box {
                <xc-0.15,yc,zc>
                <xc,yc+lcorpo,zc-hcorpo>
        }
}
#end

#declare ltotalperna = 0.7;
#declare ltotalabraco = 0.5;
#macro abraco(xc,yc,zc,rab,rb)
        union {
        cylinder{
                <xc,yc,zc>
                <xc,yc+ltotalabraco,zc>
                0.5*rjunta
        }
        junta(xc,yc+ltotalabraco,zc)
        braco(xc,yc+ltotalabraco+rjunta,zc,rb)
        translate<-xc,-yc,0>
        rotate<0,0,rab>
        translate<xc,yc,0>
        }
#end

#macro braco(xc,yc,zc,rb)
        union {
        cylinder{
                <xc,yc,zc>
                <xc,yc+ltotalabraco,zc>
                0.5*rjunta
        }
        translate<-xc,-yc,0>
        rotate<0,0,rb>
        translate<xc,yc,0>
        }
#end

#macro coxa(xc,yc,zc,rab,rb,rp)
        union {
        cylinder{
                <xc,yc,zc>
                <xc,yc,zc-ltotalperna>
                0.5*rjunta
        }
        junta(xc,yc,zc-ltotalperna)
        perna(xc,yc,zc-ltotalperna-rjunta,rb,rp)
        translate<-xc,0,-zc>
        rotate<0,rab,0>
        translate<xc,0,zc>
        }
#end

#macro perna(xc,yc,zc,rb,rp)
        union {
        cylinder{
                <xc,yc,zc>
                <xc,yc,zc-ltotalperna>
                0.5*rjunta
        }
        pe(xc,yc,zc-ltotalperna,rp)
        translate<-xc,0,-zc>
        rotate<0,rb,0>
        translate<xc,0,zc>
        }
#end

#declare NQ = 6;

#declare pe_esq = array[NQ]     {0,-90,0,90,0,0};
#declare pe_dir = array[NQ]     {0,90,0,-90,0,0};
#declare perna_esq = array[NQ]  {0,0,60,60,0,0};
#declare perna_dir = array[NQ]  {0,0,60,60,0,0};
#declare coxa_esq = array[NQ]   {0,0,-30,-30,0,0};
#declare coxa_dir = array[NQ]   {0,0,-30,-30,0,0};
#declare abraco_esq = array[NQ] {0,0,-105,0,0,0};
#declare abraco_dir = array[NQ] {0,-105,0,0,-105,0};
#declare braco_esq = array[NQ]  {0,-110,-110,-105,-90,0};
#declare braco_dir = array[NQ]  {0,-75,-75,-105,-75,0};
#declare tempo = array[NQ] {0,0.2,0.4,0.6,0.8,1.0};

#macro quadro_anterior(fase)
        #local i=0;

        #while (i < NQ-1)
                #if ((tempo[i] <= fase) & ((tempo[i+1] >= fase) | (i = NQ-1)))
                        #local resp = i;
                #end
        #local i = i + 1;
        #end
        resp
#end

#macro interpola(f0,v0,f1,v1,f)
        #local ss = (f-f0)/(f1-f0);
        #local rr = 1-ss;

        (rr*v0+ss*v1)
#end

#macro boneco_dancando(fase)
        #local i = quadro_anterior(fase);
        #local pe_esq_t = interpola( tempo[i], pe_esq[i], tempo[i+1], pe_esq[i+1], fase);
        #local pe_dir_t = interpola( tempo[i], pe_dir[i], tempo[i+1], pe_dir[i+1], fase);
        #local abraco_dir_t = interpola( tempo[i], abraco_dir[i], tempo[i+1], abraco_dir[i+1], fase);
        #local abraco_esq_t = interpola( tempo[i], abraco_esq[i], tempo[i+1], abraco_esq[i+1], fase);
        #local braco_esq_t = interpola( tempo[i], braco_esq[i], tempo[i+1], braco_esq[i+1], fase);
        #local braco_dir_t = interpola( tempo[i], braco_dir[i], tempo[i+1], braco_dir[i+1], fase);
        #local coxa_esq_t = interpola( tempo[i], coxa_esq[i], tempo[i+1], coxa_esq[i+1], fase);
        #local coxa_dir_t = interpola( tempo[i], coxa_dir[i], tempo[i+1], coxa_dir[i+1], fase);
        #local perna_dir_t = interpola( tempo[i], perna_dir[i], tempo[i+1], perna_dir[i+1], fase);
        #local perna_esq_t = interpola( tempo[i], perna_esq[i], tempo[i+1], perna_esq[i+1], fase);
        #local k=5;
                object{coelho_de_botas(pe_esq_t,pe_dir_t,abraco_dir_t,braco_dir_t, abraco_esq_t,braco_esq_t,coxa_esq_t,perna_esq_t,coxa_dir_t,  perna_dir_t)}

#end

#macro coelho_de_botas(rotpe_dir,rotpe_esq,r_ab_esq,
r_b_esq,r_ab_dir,r_b_dir,rcd,rpd,rce,rpe)
#declare xcorpo = 0;
#declare ycorpo = 0;
#declare zcorpo = 0;
union {
        cabeca(xcorpo,ycorpo+lcorpo/2,zcorpo+raio_cabeca)
        corpo(xcorpo,ycorpo,zcorpo)
        junta(xcorpo-rjunta,ycorpo-rjunta,zcorpo-rjunta)//besq
        junta(xcorpo-rjunta,ycorpo+rjunta+lcorpo,zcorpo-rjunta)//bdir
        junta(xcorpo-rjunta,ycorpo+rjunta,zcorpo-hcorpo-rjunta)
        junta(xcorpo-rjunta,ycorpo+lcorpo-rjunta,zcorpo-hcorpo-rjunta)

        abraco(xcorpo-rjunta,ycorpo+2*rjunta+lcorpo,zcorpo-rjunta,r_ab_dir,r_b_dir)

        union{
        abraco(xcorpo-rjunta,ycorpo+2*rjunta,zcorpo-rjunta,r_ab_esq,r_b_esq)
        scale<1,-1,1>
        }

        coxa(xcorpo-rjunta,ycorpo+rjunta,zcorpo-hcorpo-2*rjunta,rce,rpe,rotpe_esq)

        coxa(xcorpo-rjunta,ycorpo+lcorpo-rjunta,zcorpo-hcorpo-2*rjunta,rcd,rpd,rotpe_dir)

}
#end

union{

        object{ boneco_dancando(clock) texture{tx_fosca} }
}

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 1.00 >;
#declare raio_cena = 14;
#declare dir_camera = < 14.00, 7.00, 4.00 >;
#declare dist_camera = 16.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)