// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2010-03-04 15:44:01 by stolfi

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_chao =
  texture{
    pigment{ color rgb < 0.00, 0.70, 0.00 > }
    scale 2.0
  }

// ======================================================================
// DESCRIÇÃO DA CENA 

#declare raio = 2.000;

// Partes da cena:

#declare chao = 
  box{ <-20,-20,-1>, <+20,+20,0> }

#macro cabeca()
  object{ sphere { < 0.00, 0.00, 0.00 >, 0.5 texture {
        pigment { color rgb <0.64, 0.16, 0.16> }
      } }  }
#end

#macro tronco()
  object{ box{ <-0.50, -0.70, -1>, <0.50, 0.70, 1> texture {
        pigment { color rgb <0.64, 0.16, 0.16> }
      }}  }
#end

#macro pescoco()
  object {
    cylinder {
      < 0, 0, 0 >,
      < 0, 0, 0.80 >,
      0.15
      texture{ pigment { color rgb <0.64, 0.16, 0.16> } }
    }
  }
#end

#macro orelha()
  object {
    cone {
      < 0, 0, 0>, 0.15,
      < 0, 0, 0.8>, 0
      texture{ pigment { color rgb <0.64, 0.16, 0.16> } }
    }
  }
#end

#macro pe()
  union {
    object{ 
      sphere { 
        < 0.00, 0.00, 0.00 >, 0.15 
        texture {
          pigment { color rgb <1, 1, 1> }
        } 
      }
    }
  
    object{
      box { 
        <-0.05, -0.10 ,-0.40>, <0.05, 0.10, 0> 
        texture {
          pigment { color rgb <1, 1, 1> }
        }
      }
    }
  }
#end

#macro canela(c)
  union {
    object{ 
      sphere { 
        < 0.00, 0.00, 0.00 >, 0.20 
        texture {
          pigment { color rgb <0.64, 0.16, 0.16> }
        } 
      }
    }
  
    object{
      box { 
        <-0.10, -0.10 ,-1>, <0.10, 0.10, 0> 
        texture {
          pigment { color rgb <0.64, 0.16, 0.16> }
        }
      }
    }

    object{pe() rotate <0,c,0> translate <0,0,-1>}
  }
#end

#macro coxa(b,c)
  union {
  object{ 
    box { 
      <-0.15, -0.15 ,-1>, <0.15, 0.15, 0> 
      texture {
        pigment { color rgb <0.64, 0.16, 0.16> }
      }
    }
  }
  object{canela(c) rotate <0,b,0> translate <0,0,-1>}
  }
#end

#macro perna(a,b,c)
  object{coxa(b,c) rotate <0,a,0>}
#end

#macro mao()
  object{ 
    sphere { 
      < 0.00, 0.00, 0.00 >, 0.15 
      texture {
        pigment { color rgb <1, 1, 1> }
      } 
    }
  }
#end

#macro parte_braco(b)
  union{
    object{ 
      box { 
        <-0.15, -0.15 ,-1>, <0.15, 0.15, 0> 
        texture {
          pigment { color rgb <0.64, 0.16, 0.16> }
        }
      }
    }
    object{antebraco() rotate <0,b,0> translate <0,0,-1>}
  }

#end

#macro antebraco()
  union {
    object{ sphere { < 0.00, 0.00, 0.00 >, 0.20 texture {
          pigment { color rgb <0.64, 0.16, 0.16> }
        } }  }
  
    object{
      box { 
        <-0.10, -0.10 ,-1>, <0.10, 0.10, 0> 
        texture {
          pigment { color rgb <0.64, 0.16, 0.16> }
        }
      }
    }
    object{mao() translate <0,0,-1>}
  }
#end

#macro braco(a,b)
  object{parte_braco(b) rotate <0,a,0>}
#end

#macro gatoDeRelogio(a1bd,a2bd,a1be,a2be,a1pd,a2pd,a3pd,a1pe,a2pe,a3pe)
union{
  object{cabeca() translate <0,0,3.7>}
  object{tronco() translate <0,0,2>}
  object{pescoco() translate <0,0,3>}
  object{orelha() rotate <10,0,0> translate <0,-0.15,3.8>}
  object{orelha() rotate <-10,0,0> translate <0,0.15,3.8>}
  object{braco(a1bd,a2bd) rotate <-10,0,0> translate <0,-0.8, 3>} // braco direito
  object{braco(a1be,a2be) rotate <10,0,0> translate <0, 0.8, 3>} // braco esquerdo
  object{perna(a1pd,a2pd,a3pd) translate <0, -0.60, 1>} // perna direita
  object{perna(a1pe,a2pe,a3pe) translate <0, 0.60, 1>} // perna esquerda
}

#end

#declare NQ = 7; // num de quadros

#declare arg1 = array[NQ];
#declare arg1[0] = 0;
#declare arg1[1] = 0;
#declare arg1[2] = -60;
#declare arg1[3] = 0;
#declare arg1[4] = 0;
#declare arg1[5] = -60;
#declare arg1[6] = 0;

#declare arg2 = array[NQ];
#declare arg2[0] = 0;
#declare arg2[1] = -110;
#declare arg2[2] = -110;
#declare arg2[3] = 0;
#declare arg2[4] = -110;
#declare arg2[5] = -110;
#declare arg2[6] = 0;

#declare arg3 = array[NQ];
#declare arg3[0] = 0;
#declare arg3[1] = -110;
#declare arg3[2] = -110;
#declare arg3[3] = 0;
#declare arg3[4] = -110;
#declare arg3[5] = -110;
#declare arg3[6] = 0;

#declare arg4 = array[NQ];
#declare arg4[0] = 0;
#declare arg4[1] = 0;
#declare arg4[2] = -60;
#declare arg4[3] = 0;
#declare arg4[4] = 0;
#declare arg4[5] = -60;
#declare arg4[6] = 0;

#declare arg5 = array[NQ];
#declare arg5[0] = 0;
#declare arg5[1] = -120;
#declare arg5[2] = -120;
#declare arg5[3] = 0;
#declare arg5[4] = 0;
#declare arg5[5] = 0;
#declare arg5[6] = 0;

#declare arg6 = array[NQ];
#declare arg6[0] = 0;
#declare arg6[1] = 0;
#declare arg6[2] = 60;
#declare arg6[3] = 0;
#declare arg6[4] = 0;
#declare arg6[5] = 0;
#declare arg6[6] = 0;

#declare arg7 = array[NQ];
#declare arg7[0] = 0;
#declare arg7[1] = 0;
#declare arg7[2] = 0;
#declare arg7[3] = 0;
#declare arg7[4] = -120;
#declare arg7[5] = -120;
#declare arg7[6] = 0;

#declare arg8 = array[NQ];
#declare arg8[0] = 0;
#declare arg8[1] = 0;
#declare arg8[2] = 0;
#declare arg8[3] = 0;
#declare arg8[4] = 0;
#declare arg8[5] = 60;
#declare arg8[6] = 0;

#declare tempo = array[NQ];
#declare tempo[0] = 0.0;
#declare tempo[1] = 0.17;
#declare tempo[2] = 0.34;
#declare tempo[3] = 0.51;
#declare tempo[4] = 0.68;
#declare tempo[5] = 0.85;
#declare tempo[6] = 1.0;

#macro interpola(f0,v0,f1,v1,f)
  #local ss = (f - f0) / (f1 - f0);
  #local rr = 1 - ss;
  (rr * v0 + ss * v1)
#end

#macro quadro_anterior(fase)
  #local i = 0;

  #while(i < NQ-1)
    #if((tempo[i] <= fase) & (tempo[i+1] >= fase))
      #local resp = i;
    #end
    #local i = i + 1;
  #end
  resp
#end

#macro gatoDeRelogioDancando(fase)
  #declare pE3 = -90;
  #declare pD3 = -90;

  #local q = quadro_anterior(fase);

  #local ta = fase;

  #declare bD2 = interpola(tempo[q],arg1[q],tempo[q+1],arg1[q+1],ta); // braco direito - cotovelo
  #declare bD1 = interpola(tempo[q],arg2[q],tempo[q+1],arg2[q+1],ta); // braco direito - ombro
  #declare bE1 = interpola(tempo[q],arg3[q],tempo[q+1],arg3[q+1],ta); // braco esquerdo - ombro
  #declare bE2 = interpola(tempo[q],arg4[q],tempo[q+1],arg4[q+1],ta); // braco esquerdo - cotovelo
  #declare pD1 = interpola(tempo[q],arg5[q],tempo[q+1],arg5[q+1],ta); // perna direita - coxa
  #declare pD2 = interpola(tempo[q],arg6[q],tempo[q+1],arg6[q+1],ta); // perna direita - joelho
  #declare pE1 = interpola(tempo[q],arg7[q],tempo[q+1],arg7[q+1],ta); // perna esquerda - coxa
  #declare pE2 = interpola(tempo[q],arg8[q],tempo[q+1],arg8[q+1],ta); // perna esquerda - joelho

  object{gatoDeRelogio(bD1,bD2,bE1,bE2,pD1,pD2,pD3,pE1,pE2,pE3) translate <0,0,1>}
#end


#include "eixos.inc"

// Aqui está a cena, finalmente:

union{
  object{chao translate < 0,0,-0.2 > texture{ tx_chao } }
  gatoDeRelogioDancando(clock)
}

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 1.00 >;
#declare raio_cena = 8.0;
#declare dir_camera = < 50.00, 35.00, 20.00 >;
#declare dist_camera = 20.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)