// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2003-09-04 15:25:26 by stolfi

// ======================================================================
// CÂMERA 

camera {
  location  <  8.00, 4.00, 2.00 >  // Posição do observador.
  right     -0.75*x           // Largura RELATIVA da imagem.
  up        1.00 *y                 // Altura RELATIVA da imagem.      
  sky       z                      // Qual direção é "para cima"?
  look_at  0.3* <  0.00, 0.00, 7.5 >  // Para onde a câmera está apontando.
} 
// Nota: os parâmetros "right" e "up" devem ter a mesma proporção
// que os parâmetros ${WIDTH} e ${HEIGHT} no Makefile.

// ======================================================================
// FONTES DE LUZ

light_source {
  10 * < +50.0, +30.0, +50.0 >              // Posição da lâmpada.
  color rgb 1.2 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

light_source {
  10 * < +50.0, +10.0, +10.0 >             // Posição da lâmpada.
  color rgb 0.8 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

// ======================================================================
// DESCRIÇÃO DA CENA 

background{ color rgb <0, 1.0, 0.0 > }

#declare raio = 2.000;

#declare tinta_A = 
  texture {
    pigment { color rgb < 0.10, 0.80, 1.00 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }

#declare tinta_B = 
  texture {
    pigment { color rgb < 1.00, 0.0, 0.8 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }

  
#declare esferas =
 union{
 	#declare m = 0;
	#while(m<8)
		sphere{ 0.4*<m,m,m>, 0.1 texture{tinta_A}}
		#declare m = m+2;
	#end
}

#declare cilindro = 
cylinder {
	0.3*<0,0,0>,
	<2.4,2.4,2.4>
	0.02
	texture{tinta_B}
	}

#declare circulos =
union{
	#declare p=1.15;
	#declare s=0.8;
	#while (p<4.6)
		torus {p, 0.01 texture{tinta_B} rotate 90*x translate<0,0,s>}
		#declare p = p + 1.15;
		#declare s = s + 0.8;
	#end
}

// Aqui está a cena, finalmente:

  union {
	object{cilindro}
	object{esferas}
	object{circulos}
	#declare n=40;
	#while(n<360)
	object{esferas rotate n*z}
	object{cilindro rotate n*z}
	#declare n = n+40;
	#end
    }