// Last edited on 2005-01-05 23:22:56 by stolfi
// Processed by remove-cam-lights

#include "colors.inc"

#declare fonte=seed(314159);

sky_sphere {
  pigment {
    gradient y
    color_map {
      [0.0 rgb <0.6,0.7,1.0>]
      [0.7 rgb <0.0,0.1,0.8>]
    }
  }
}

plane {
  y, -1
  pigment { color rgb <0.7,0.5,0.3> }
}

#declare tx_espelho =
  texture{
    pigment {Gray70}
    finish{
      ambient 0.05 diffuse 0.05
      reflection{
         Silver
         metallic
       }
      specular 0.20 roughness 0.05
    }
  }

#declare tx_pedras =
  texture{
     finish {
         ambient 0.1 diffuse 0.1 reflection 0.25
         specular 1 roughness 0.001
     }
     pigment {color rgb <0, 1, 1>}
  }

#declare dedo =
cylinder{
   0, <1,0,0>,
   0.18
   pigment {color Cyan}
}

#declare juncao =
sphere{
   0, 0.75
   pigment {color Green}
}

#declare mao =
 #declare t1 = clock;
 union{
  box{
     <0,-1,-0.5> <2, 1, 0.5>
     pigment{color Blue}
  }

  object{
    dedo
    rotate -60*t1*y
    translate<1.9,0,0>
  }
  object{
    dedo

    translate<1.9,0.55,0>
  }
  object{
    dedo
    rotate -40*t1*y
    translate<1.9,-0.55,0>
  }
}

#declare antebraco =
 #declare t2 = clock;
 union{

   cylinder{
    0, <6,0,0>
    0.75
    pigment {color Yellow}
   }

   object{
     juncao
     translate <6.75, 0, 0>
   }

   object {
    mao
    rotate 45*t2* x
    translate <7.5,0,0>
   }

}

#declare braco =
 #declare t3 = clock;
 union{

  cylinder{
   0, <9,0,0>
   0.75
   pigment {color Yellow}
  }

  object {
     juncao
     translate <9.75,0,0>
  }

 object {
    antebraco
    rotate 50*t3*z
    translate <10.5,0,0>
  }

 object {
   juncao
   translate <-0.75,0,0>
 }

}

#declare t4 = clock;
object{braco rotate -50*t4*y }

#include "camlight.inc"
camlight(<5,0,0>,vrotate(<0,-5,-46>,10*x),1.00,y,1.0)