#include "colors.inc"

camera {
  location  < 50, 50, 50 >
  right     -1.00*x                // Largura RELATIVA da imagem.
  up        0.75*y                 // Altura RELATIVA da imagem.      
  sky       y                      // Qual direção é "para cima"?
  look_at   < 15, -20, 0 >  // Para onde a câmera está apontando.
} 

light_source {
  //1 * < 10.0, 10.0, -10.0 >              // Posição da lâmpada.
  <100, 180, 100>
  color rgb 5 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
}

background{ color rgb <0.75,0.8,0.85> }

#declare marrom1 = <0.7,0.4,0.2>;
#declare marrom2 = <0.6,0.3,0.1>;
#declare marrom3 = <0.8,0.3,0.1>;
#declare marrom4 = <0.9,0.2,0.1>;

#declare dedos =
  union {
    // 4 DEDOS !!!
    #declare i = 0;
    #while(i<4)
      #declare dedo = 
      cylinder {
        <0,0,0>, <6,0,0>, 0.8
        pigment {color marrom1}
      }
      object {dedo translate <0,i*2,0>}
      #declare i=i+1;
    #end
  }

#declare mao =
  union {
    cylinder {
        <0,7.6,0>, <4,7.6,0>, 0.8
        pigment {color marrom1}
    }
    box { 
      <0,-0.8,-0.8>,<8,6.8,0.8> 
      pigment {color marrom2 }
    }
    object {dedos rotate 90*clock*y  translate <8,0,0>}
  }

#declare cotovelo =
  union {
    cylinder {
        <0,3,0>, <20,3,0>, 3
        pigment {color marrom3}
    }
    object {mao rotate 30*clock*x translate <20,0,0>}
  }

#declare braco =
  union {
    cylinder {
        <0,0,0>, <0,-20,0>, 3
        pigment {color marrom4}
    }
    object {cotovelo rotate 30*clock*z translate <2,-20,0>}
  }

object {braco rotate 45*clock*z}