// Last edited on 2005-01-06 02:05:00 by stolfi
// Processed by remove-cam-lights

background{
  color rgb <0.75, 0.80, 1.0>
}

#declare vidro =
  texture {
    pigment { rgb <0.7,0.7,0.7> filter 0.8 }
    finish { diffuse 0.08
             specular 0.2
             roughness 0.001
             ambient 0.03
             reflection 0.10
           }
  }

#declare parede =
  texture {
    pigment { rgb < 0.60, 0.80, 1.0> }
    finish { diffuse 0.8 ambient 0.2 }
  }

#declare parede_i =
  texture {
    pigment { rgb < 1.00, 1.00, 0.60> }
    finish { diffuse 0.8 ambient 0.2 }
  }

#declare sombrinha = union {
    cone {
      <0, 0, 2.5>, 0.0
      <0, 0, 2>, 1.5
      pigment { rgb <0.1, 0, 0> }
    }
    cylinder {
      <0, 0, 0>,
      <0, 0, 2>,
      0.05
      open
      pigment { rgb <0,0,0> }
    }
  }

#declare predio =
  box {
    <0, -6, -1>,
    <-50, 6, 14>
    texture { parede }
  }

#declare terraco =
  box {
    <-0.1, -5.9, 13>,
    <-49.9, 5.9, 14.1>
    texture { parede }
  }

#declare corredor =
  box {
    <0.0, -1, 0.01 >,
    <-49.9, 1, 1.9>
    texture { parede }
  }

#declare sacada =
  box {
    <1, -5, 0>,
    <-2, 5, 1.9>
    texture { parede }
  }

#declare barra =
  cylinder {
    <-0.1, -5, 1>,
    <-0.1, 5, 1>,
    0.1
    open
    pigment { rgb <0,0,0> }
  }

#declare porta =
  box {
    <1, -2, -0.99>,
    <-49.9, 2, 2.0>
    texture { parede }
  }

#declare janela =
  box {
    <0, -0.1, 0>,
    <-1.5, 0.1, 1>
    texture { parede_i }
  }

#declare janela_a =
  box {
    <0, 0, -0.5>,
    <-1.5, 0.01, 0.5>
    texture { vidro }
    rotate -45*x
    translate -0.4*y
    translate 0.5*z
  }

#declare janela_f =
  box {
    <0, 0, -0.5>,
    <-1.5, 0.01, 0.5>
    texture { vidro }
  }

#declare botao =
  cylinder {
    <0, 0, 0>,
    <0.01, 0, 0>,
    0.4
    texture { vidro }
  }

union {
  difference {

    object { predio }
    object { terraco }
    object { porta }

    #declare i = 0;
    #while(i < 5)
      object { corredor translate (3 + i*2)*z}
      object { sacada translate (3 + i*2)*z}
      #declare i = i + 1;
    #end

    #declare i = 0;
    #while(i < 5)
      #declare j = 0;
      #while(j < 10)
        object { janela translate 6*y
                        translate -(3 + j*5)*x
                        translate (4 + i*2)*z}
        object { janela translate -6*y
                        translate -(3 + j*5)*x
                        translate (4 + i*2)*z}

        object { janela_a translate 7*y
                        translate -(3 + j*5)*x
                        translate (4 + i*2)*z}
        object { janela_a translate -7*y
                        translate -(3 + j*5)*x
                        translate (4 + i*2)*z}
        #declare j = j + 1;
      #end
      #declare i = i + 1;
    #end
  }

  #declare gerador = seed(12345);
  #declare i = 0;
  #while(i < 5)
    #declare j = 0;
    #while(j < 10)
      #if(2*rand(gerador) > 1)
        object { janela_a rotate 90*x
                      translate 6*y
                      translate -(3 + j*5)*x
                      translate (4 + i*2)*z}
      #else
        object { janela_f translate 6*y
                      translate -(3 + j*5)*x
                      translate (4 + i*2)*z}
      #end
      #if(2*rand(gerador) > 1)
        object { janela_a translate -6*y
                      translate -(3 + j*5)*x
                      translate (4 + i*2)*z}
      #else
        object { janela_f translate -6*y
                      translate -(3 + j*5)*x
                      translate (4 + i*2)*z}
      #end
      #declare j = j + 1;
    #end
    #declare i = i + 1;
  #end

  #declare i = 0;
  #while(i < 5)
    object { barra translate (3 + i*2)*z}
    #declare i = i + 1;
  #end

  #declare i = 0;
  #while(i < 15)
    object { sombrinha translate 13*z
                       translate -20*rand(gerador)*x
                       translate (-6 + 12*rand(gerador))*y}
    #declare i = i + 1;
  #end

  object { botao translate -4*y translate 13.5*z }
}

plane { z, -1
  pigment { rgb < 0.40, 0.40, 0.40> }
}

#include "camlight.inc"
camlight(<-10,-5,5>,<30,-15,15>,1.00,z,1.0)