// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2003-09-04 15:25:26 by stolfi

// ======================================================================
// CÂMERA 

camera {
  location  <  8.00, 4.00, 2.00 >  // Posição do observador.
  right     -0.75*x                // Largura RELATIVA da imagem.
  up        1.00*y                 // Altura RELATIVA da imagem.      
  sky       z                      // Qual direção é "para cima"?
  look_at   <  0.00, 0.00, 0.00 >  // Para onde a câmera está apontando.
} 
// Nota: os parâmetros "right" e "up" devem ter a mesma proporção
// que os parâmetros ${WIDTH} e ${HEIGHT} no Makefile.

// ======================================================================
// FONTES DE LUZ

light_source {
  10 * < +50.0, +30.0, +50.0 >              // Posição da lâmpada.
  color rgb 1.2 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

light_source {
  10 * < +50.0, -10.0, +10.0 >             // Posição da lâmpada.
  color rgb 0.8 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

// ======================================================================
// DESCRIÇÃO DA CENA 

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare raio = 2.000;

#declare cor_ouro = <1.0, 0.8, 0.1>;
#declare ouro =
  texture {
    pigment { rgb cor_ouro }
    finish {
      ambient 0.05 diffuse 0.05 reflection cor_ouro
      specular 0.20 roughness 0.05
    }
  }

#declare diamante = <0.5,0.5,0.5>;
#declare pedra_branca = 
  texture {
    pigment { color diamante filter 1 }
    finish { diffuse 0.1 specular 1 roughness 0.001 ambient 0.1 
             reflection 0.25}
  }

#declare ruby = <0.9,0.5,0.5>;
#declare pedra_vermelha = 
  texture {
    pigment { color ruby filter 1 }
    finish { diffuse 0.1 specular 1 roughness 0.001 ambient 0.1 
             reflection 0.25}
  }

#declare safira = <0,0,1>;
#declare pedra_azul = 
  texture {
    pigment { color safira filter 1 }
    finish { diffuse 0.1 specular 1 roughness 0.001 ambient 0.1 
             reflection 0.25}
  }

#declare branco = 
  texture {
    pigment { color rgb < 0.9, 0.9, 0.9 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }
  
#declare conedentro =
  union {
    cone {
      <0,0,0.4>, 0.4
      <0,0,3.0>, 0.1 
      texture { ouro }
    }
    sphere {
      <0,0,3.2>, 0.2
      texture { pedra_branca }
      interior { ior 1.5 }
    }
  }

#declare conelado =
  union {
    cone {
      <0,0,0>, 0.4
      <0,0,2.6>, 0.1 
      texture { ouro }
    }
    sphere {
      <0,0,2.8>, 0.2
      texture { pedra_vermelha }
      interior { ior 1.5 }
    }
  }

#declare pedralado =
    sphere {
      <2.0,0.4,0.6>,0.1
      texture { pedra_azul }
      interior { ior 1.5 }
    }

#declare cilindro = 
  cylinder {
    <0,10,2.3>
    <0,-10,2.3>
    0.75
  }

#declare coroa = 
  difference {
    lathe {
	8
	<2.0,0.4>
	<2.0,0.8>
	<2.4,1.0>
	<2.0,1.2>
	<2.0,2.3>
	<1.8,0.8>
	<1.8,0.0>
	<0.0,0.0>
        texture { ouro }
        rotate 90*x
    }
    object { cilindro}
    object { cilindro 
	     rotate 45*z}
    object { cilindro 
	     rotate 90*z}
    object { cilindro 
	     rotate 135*z}
  }
  
#declare partebaixo = 
  torus {
    2
    0.2
    texture { branco }
  }

#declare plano =
  plane {
    z,0
    texture {
      pigment { checker <0,0,0>, <1,1,1> }
      finish { ambient 0.1 diffuse 0.9 }
      scale 0.5
    }
  }
  
// Aqui está a cena, finalmente:

  union {
    object { coroa }
    object { conedentro}
    object { conelado
	     translate <0,1.2,0> }
    object { conelado
	     translate <0,-1.2,0> } 
    object { plano } 
    object { partebaixo 
	     rotate 90*x
             translate <0,0,0.2>} 
    object { pedralado }
    object { pedralado 
             rotate 45*z }
    object { pedralado 
             rotate 90*z }
    object { pedralado 
             rotate 135*z }
    object { pedralado 
             rotate 180*z }
    object { pedralado 
             rotate 225*z }
    object { pedralado 
             rotate 270*z }
    object { pedralado 
             rotate 315*z }
  }