// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2003-09-04 15:25:26 by stolfi

// ======================================================================
// CÂMERA 

camera {
  location  <  0.00, 10.00, 45.00 >  // Posição do observador.
  right     -0.75*x                   // Largura RELATIVA da imagem.
  up        1.00*z                 // Altura RELATIVA da imagem.      
  sky       y                      // Qual direção é "para cima"?
  look_at   <  0.00, 5.00, 0.00 >  // Para onde a câmera está apontando.
} 
// Nota: os parâmetros "right" e "up" devem ter a mesma proporção
// que os parâmetros ${WIDTH} e ${HEIGHT} no Makefile.

// ======================================================================
// FONTES DE LUZ

//light_source {
//  10 * < 20.0, 0.0, 0.0 >              // Posição da lâmpada.
//  color rgb 0.4 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
//} 

light_source {
   2 * < 0.0, 20.0, 3.0 >             // Posição da lâmpada.
   color rgb 2.0 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

light_source {
  1 * < 0.0, 5.0, 20.0 >             // Posição da lâmpada.
  color rgb 0.6 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

// ======================================================================
// DESCRIÇÃO DA CENA 

background{ color rgb < 0.75, 0.80, 0.85 > }
#declare cor_dourada = < 0.80, 0.80, 0.05 >;
#declare tinta_dourada = 
  texture {
    pigment { rgb cor_dourada }
    finish { diffuse 0.05 specular 0.20 roughness 0.05 
             ambient 0.05 reflection cor_dourada }
  }

#declare cor_prateada = < 0.90, 0.90, 0.90 >;
#declare tinta_prateada = 
  texture {
    pigment { rgb cor_prateada }
    finish { diffuse 0.05 specular 0.20 roughness 0.05 
             ambient 0.05 reflection cor_prateada }
  }

#declare tinta_rubi = 
  texture {
    pigment { color rgb < 0.80, 0.30, 0.30 > filter 1 }
    finish { diffuse 0.1 specular 1 roughness 0.0001 
             ambient 0.1 reflection 0.25 }
  }

#declare tinta_esmeralda = 
  texture {
    pigment { color rgb < 0.15, 0.70, 0.15 > filter 1 }
    finish { diffuse 0.1 specular 1 roughness 0.0001 
             ambient 0.1 reflection 0.25 }
  }

#declare chao =
  plane {
    y,
    -3
    texture {
      pigment { checker <0.20, 0.20, 0.05>, <0.10, 0.10, 0.25> }
      finish {ambient 0.1 diffuse 0.9}
      scale 3
    }
  }

#declare coroa =
  lathe {
    bezier_spline
    16,
    <12.00, 1.00>, <12.00, 1.50>, <13.00, 3.50>, <12.00, 4.00>
    <12.00, 4.00>, <13.00, 4.50>, <11.00, 6.50>, <12.00, 7.00>
    <11.50, 7.00>, <10.50, 6.50>, <12.50, 4.50>, <11.50, 4.00>
    <11.50, 4.00>, <12.50, 3.50>, <11.50, 1.50>, <11.50, 1.00>
    texture { tinta_dourada }
  }
  
#declare base =
  torus {
    11.75, 0.50
    translate <0.00, 0.70, 0.00>
    texture { tinta_prateada }
  }

#declare rubi = 
  sphere {
    <0.00, 5.50, 11.75>, 0.7
    texture { tinta_rubi }
  }

#declare esmeralda = 
  sphere {
    <8.50, 2.50, 8.50>, 0.7
    texture { tinta_esmeralda }
  }

// Aqui está a cena, finalmente:

union {
  object { base }
  object { base translate <0.00, 6.60, 0.00> }
  object { coroa }
  object { chao }
  object { rubi }
  object { esmeralda }
  object { esmeralda translate <-17.00, 0.00, 0.00> }
}