// ======================================================================
// CÂMERA 

camera {
  location  < 30, .0, .00 >  // Posição do observador.
  right     -1.0*x                 // Largura RELATIVA da imagem.
  up        0.75*y                 // Altura RELATIVA da imagem.      
  sky       z                      // Qual direção é "para cima"?
  look_at   <  0.00, 0.00, 0.00 >  // Para onde a câmera está apontando.
} 
// Nota: os parâmetros "right" e "up" devem ter a mesma proporção
// que os parâmetros ${WIDTH} e ${HEIGHT} no Makefile.

// ======================================================================
// FONTES DE LUZ

light_source {
  < 0.0, 0.0, 20.0 >              // Posição da lâmpada.
  color rgb 2 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

light_source {
  < 20.0, 0.0, 0.0 >             // Posição da lâmpada.
  color rgb 2 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 


// ======================================================================
// DESCRIÇÃO DA CENA 

background{ color rgb < 0.0, 0.0, 0.0 > }


#declare vidro = 
  texture {
    pigment { color rgb < 1.0, 1.0, 1.0 > filter 0.8}
    finish { diffuse 0.0 specular 0.0 reflection 0.1 roughness 0.0 ambient 0.1 }
  }
#declare cor_espelho = < 0.90, 0.90, 1.0 >;
#declare espelho = 
  texture {
    pigment { color rgb  cor_espelho}
    finish { diffuse 0.1 specular 0.1 roughness 0.05 ambient 0.05 reflection 0.7*cor_espelho}
  }
#declare preto=texture{
    pigment { color rgb  <0.1,0.1,0.1>}
    finish { diffuse 0.4 specular 0.20 roughness 0.05 ambient 0.05 reflection 0.3}
}

#declare texchao = 
  texture {
    pigment {color <0.5,0.5,0.5>}
  }

#declare texmundo = 
texture {
pigment{image_map{png "terra.png" map_type 1} rotate<0,-60,160> rotate<-90,0,0> scale<1,-1,1>}

}


#declare mundo = 
blob {
threshold 0.1
sphere{<0,0,0> 10 1}
sphere{<5,1.5,1>+clock*<3,0,0> 2 2}
sphere{<5,1,2>+clock*<3,0,0>  2 2}
sphere{<5,0.5,2>+clock*<3,0,0>  2 2}
sphere{<5,1.3,-0.5>+clock*<3,0,0>  1.5 2}
texture{texmundo}
}


#declare s=seed(0);
#declare ceu = 
union {
#declare cont=0;
#while (cont<10000)
sphere{<1000,0,0> 1 pigment{color rgb<1,1,1>} rotate <rand(s)*360, rand(s)*360, rand(s)*360>}
#declare cont=cont+1;
#end
}

union {
object {mundo rotate<0,0,clock*45-30> rotate<15, 15, 0>}
object{ceu}
}