// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2003-07-31 12:50:37 by stolfi

// ======================================================================
// CÂMERA 

camera { 
  location  <  20, 0, 0 >  // Posição do observador.
  right     -1.0*x                 // Largura RELATIVA da imagem.
  up        0.75*y                 // Altura RELATIVA da imagem.      
  sky       z                      // Qual direção é "para cima"?
  look_at   <  0.00, 0.00, 0.00 >  // Para onde a câmera está apontando.
} 
// Nota: os parâmetros "right" e "up" devem ter a mesma proporção
// que os parâmetros ${WIDTH} e ${HEIGHT} no Makefile.

// ======================================================================
// FONTES DE LUZ

light_source {
  2*< 4, -4, 3 >
  color rgb 1.0 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

light_source {
  10 * < -1.0, -1.0, -3.0 >             // Posição da lâmpada.
  color rgb 1.8 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

#include "colors.inc"

// ======================================================================
// DESCRIÇÃO DA CENA 

sky_sphere {

    pigment {
      gradient z
      color_map {
        [0.000 0.002 color rgb <1.0, 0.2, 0.0>
                     color rgb <1.0, 0.2, 0.0>]
        [0.002 0.200 color rgb <0.8, 0.1, 0.0>
                     color rgb <0.2, 0.2, 0.3>]
      }
      scale 2
      translate -1
    }

    pigment {
      bumps
      color_map {
          [0.0 0.1 color rgb <0.85, 0.85, 0.85>
                   color rgb <0.75, 0.75, 0.75>]
          [0.1 0.5 color rgb <0.75, 0.75, 0.75>
                   color rgbt <1, 1, 1, 1>]
          [0.5 1.0 color rgbt <1, 1, 1, 1>
                   color rgbt <1, 1, 1, 1>]
      }

      scale <0.2, 0.5, 0.2>
    }

    rotate -135*x
  }

#declare cristal_branco =
  texture {
	pigment { color rgb < 0.9, 0.9, 0.9 > filter 1.0 }
	finish {
	  ambient 0.1 diffuse 0.1
	  reflection 0.25
	  specular 1 roughness 0.001
	}
  }

#declare dourado =
  texture {
	pigment { Yellow }
	finish {
	  ambient 0.05 diffuse 0.05
	  reflection Yellow
	  specular 0.20 roughness 0.05
	  metallic
	}
  }


#declare cromo =
  texture {
	pigment { Gray80 }
	finish {
	  ambient 0.05 diffuse 0.05
	  reflection Gray75
	  specular 0.20 roughness 0.05
	  metallic
	}
  }


#declare pedra =
intersection {
  cylinder { 
    3*<-1,0,0>
    3*<1,0,0>
    3
  }
  cylinder { 
    3*<0,-1,0>
    3*<0,1,0>
    3
  }
  no_shadow

}

#declare letra_L =
text {

  ttf "comic.ttf" "L" 0.5, 0
  rotate 90*z
  rotate 90*y
  scale 4

  translate < 0, -1, -1 >

  pigment { Yellow }
  finish {
    ambient 0.05 diffuse 0.05
    reflection 0.3*DarkBrown
    specular 0.20 roughness 0.05
    metallic
  }

}

#declare letra_I =
text {

  ttf "comic.ttf" "I" 0.5, 0
  rotate 90*z
  rotate 90*y
  scale 4

  translate < 0, -1, -1 >

  pigment { Blue }
  finish {
    ambient 0.05 diffuse 0.05
    reflection 0.3*DarkBrown
    specular 0.20 roughness 0.05
    metallic
  }

}

#declare letra_V =
text {

  ttf "comic.ttf" "V" 0.5, 0
  rotate 90*z
  rotate 90*y
  scale 4

  translate < 0, -1, -1 >

  pigment { Green }
  finish {
    ambient 0.05 diffuse 0.05
    reflection 0.3*DarkBrown
    specular 0.20 roughness 0.05
    metallic
  }

}

#declare bolinha =
  sphere { 
    <0,0,0>
    0.3
    texture { dourado }
}

#declare diamt =
  box {
    -1*<1,1,1>
    1*<1,1,1>
    scale 0.3
    rotate 45*x
    rotate 45*y

    texture { cromo }
}

union {
	object { pedra 
	  texture { cristal_branco }
	}
	
	object { letra_L }
	translate < 0, -5, 0 >
}

union {
	object { pedra 
	  texture { cristal_branco }
	  rotate 90*z
	}
	
	object { letra_I }
	translate < 0, 0, 4 >
}

union {
	object { pedra 
	  texture { cristal_branco }
	  rotate 45*z
	}
	
	object { letra_V }
	translate < 0, 5, -2 >
}

object { bolinha 
	 translate < 0, -6, 4 >
}
object { bolinha 
	 scale 1.4
	 translate < 0, -5, 5 >
}
object { bolinha 
	 scale 1.8
	 translate < 0, -4, 6 >
}

object { diamt
	 translate < 0, 4.5, 4.5 >
}
object { diamt
	 scale 1.4
	 translate < 0, 5.3, 3.3 >
}
object { diamt
	 scale 1.8
	 translate < 0, 6.3, 2 >
}