// Last edited on 2003-12-14 23:11:46 by stolfi
// Exemplo de arquivo de descricao de cena para POV-ray

// ======================================================================

#declare ctr = < 270.00, 0.00, -140.00 > / 2;
#declare camDir = < -10 , 40, 50 >;

camera {
  location   ctr + 5.50*camDir
  right      -1.00*x
  up         1.00*y
  sky        y
  look_at    ctr
}
 

// ======================================================================
// FONTES DE LUZ

light_source {
  10 * < -20.0, 30.0, +40.0 >              // Posição da lâmpada.
  color rgb 1.2 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

light_source {
  10 * < +5.0, 30.0, 50.0 >             // Posição da lâmpada.
  color rgb 0.8 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

// ======================================================================
// DESCRIÇÃO DA CENA 

//background{ color rgb < 0.5, 0, 0.75 > }
background{ color rgb <1,1,1> }

#declare raio = 2.000;


#declare preto = 
   texture {
    pigment { color rgb < 0, 0, 0 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
} 

#declare vermelho =
  texture {
    pigment { color rgb < 1, 0, 0 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
}


#declare cinza =
 texture {
    pigment { color rgb < 0.75, 0.75, 0.75 > }
    finish { reflection < 0.75, 0.75, 0.75 > diffuse 0.05 specular 0.2 roughness 0.05 ambient 0.05 }
}


#declare marrom =
 texture {
    pigment { color rgb < 0.54, 0.27, 0.07 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
}


#declare tronco = 
 sphere {
 <0,0,0>,10
 scale <1,1.3,1>
 texture {cinza}
}


#declare olho =
 sphere {
 <0,0,0>,1
 texture {vermelho}
}

#declare boca =
 sphere {
 <0,0,0>,2
 scale <2,1,1>
 texture {preto}
}


#declare chapeu = 
 union {
 intersection {
 sphere {
 <0,0,0>,8
 }
 box {
 <8,0,8>,
 <-8,8,-8>
 }
}
 difference {
 cylinder{
 <0,0,0>,
 <0,-2,0>,
 15
}
 cylinder{
 <0,-1,0>,
 <0,-3,0>,
  15
 }
}
texture {marrom}
}
 


#declare cabeca =
union {
 difference { 
  sphere {
  <0,0,0>,10
  texture {cinza}
  }
  object {boca translate<0,0,10> rotate<20,0,0>}
  }
 object {olho translate<0,0,10> rotate<-15,-15,0> }
 object {olho translate<0,0,10> rotate<-15,15,0> }
 object {chapeu translate<0,8,0>}
}


#declare braco =
 sphere {
 <0,0,0>,5
 scale <2,1,1>
 texture {cinza}
}

#declare perna = 
 sphere {
   <0,0,0>,5
 scale <1,2,1>
 texture {cinza}
}

#declare sapato =
 intersection {
 sphere {
 <0,0,0>,5
 }
 box {
 <5,5,5>,
 <-1.5,0,-5>
 }
 scale <2,1,1>
 texture {preto}
}

#declare pernaCompleta = 
union {
 object {perna}
 object {sapato translate <0,-10,0> rotate<0,-90,0>}
}


#declare robo = 
union {
object {cabeca translate<0,20,0>}
object {pernaCompleta  rotate<0,-60,0> translate <-5,-10,0>}
object {pernaCompleta  rotate<0,60,0> translate <5,-10,0>}
object {tronco}
object {braco translate<-10,3,0>}
object {braco translate<10,3,0>}
translate <0,20,0>
}

#declare letras =
text {
 ttf "arial.ttf"
 "LIV", 0.2, 0
  texture {
  pigment { rgb <1,1,1> filter 0.9 }
  finish {
   diffuse 0.1
   reflection 0.25
   specular 0.64 roughness 0.001
  }
  }
 interior {
   ior 2
  }
}

object { letras rotate -90*x scale 100 scale <2,1,2> }

plane {
<0,1,0>,0
texture {
pigment {checker color rgb <1,1,1>, color rgb <0.7,0.7,0.7>}
} scale 20
}

#declare i=0;
#while (i < 7)
  object { robo scale 0.5 translate <7.5,20,-5-20*i>}
  #declare i = i+1;
#end

#declare i=1;
#while (i<4)
  object { robo  scale 0.5 translate <7.5+25*i,20,-5>}
  #declare i = i+1;
#end

#declare i=0;
#while (i < 7)
  object { robo scale 0.5 translate <125,20,-5-20*i>}
  #declare i = i+1;
#end

#declare i=0;
#while (i < 7)
  object { robo scale 0.5 translate <220-8.25*i,20,-5-20*i>}
  #declare i = i+1;
#end


#declare i=1;
#while (i < 7)
  object { robo scale 0.5 translate <220+8.25*i,20,-5-20*i>}
  #declare i = i+1;
#end