// Last edited on 2003-10-23 01:35:37 by stolfi
#include "colors.inc"

// ======================================================================
// CÂMERA 

#declare ctr = < 0.00, 5.00, 5.00 >;
#declare camdir = < -12.00, 17.50, 0.00 >;

camera {
  location < 0.00, 5.00, 2.50 > + 1.25*camdir
  right    1.00*x
  up       0.75*y
  sky      z
  look_at  ctr
} 

// ======================================================================
// FONTES DE LUZ

light_source {
   5*< -5.00, 25.00, 10.00 >               // Posição da lâmpada.
   color rgb 1.2*< 1.00, 1.00, 1.00 > // Intensidade e cor da luz.
} 

light_source {
   5*< -25.00, 2.00, 45.00 >               // Posição da lâmpada.
   color rgb 0.6*< 1.00, 1.00, 1.00 > // Intensidade e cor da luz.
} 

// ======================================================================
// DESCRIÇÃO DA CENA 

background { color rgb < 0.98, 1.00, 0.75 > }

#declare plano_xy =
    plane {
        < 0, 0, 1 >,
        0
    }

#declare bandeira =
   union {
      
      cylinder {
         < 0.00, 0.00, 0.00 >
         < 0.00, 0.00, 15.00 >
         0.30
         pigment { color rgb < 0.80, 0.80, 0.80 > }
      }

      box {
         < 0.30, -0.05, 10.50 >,
         < 7.80,  0.05, 15.00 >
	 pigment {
            checker rgb < 0.00, 1.00, 0.00 >, rgb < 1.00, 1.00, 0.00 >
         }
      }


   }

#declare fome =
   text {
      ttf "arial.ttf"
      "Fome Zero"
      0.15, 0
   }


union {

   object {
      plano_xy
      pigment {
         checker rgb < 1.00, 1.00, 1.00 >, < 0.70, 1.00, 1.00 >
      }
   }

   object { 
      bandeira
      rotate < 0, 25, 0>
      rotate < 0, 0, sin(3 * pi * clock) * 30>
   }

   #if (clock > 0.60)

      #declare clk = (clock - 0.60) / (1 - 0.60);

      object { 
         fome
         pigment { color rgb < 0.20, 0.50, 1.00 > }
         scale < 2.3, 2.3, 2.3 >
         rotate < 90, 0, 0 >

         rotate < 0, 0, (1 - clk) * 30 + clk * 15 >
         translate < (1 - clk) * (-12) + clk * 7,
                     (1 - clk) * 13.5 + clk * (-6),
                     0 >
      }
   #end
}