// Last edited on 2003-10-22 04:01:03 by stolfi
#include "colors.inc"
#include "stones.inc"
   
/* Título: Palácio de Fogo */
   
global_settings { max_trace_level 10 }
#declare ctr = <0,0.12,-1>;
#declare camdir = <-9.6,4.88,+7.6>;
camera {
    location ctr + 1.50*camdir
    right -1.00*x
    up 0.75*y
    sky y
    look_at  ctr
}
                                                 
light_source { 150*<0,1,1> color White fade_power 0.3 }
light_source { 150*<0,1,-1> color White fade_power 0.3 }

light_source { <3,5,3> color Red fade_power 0.3 }
light_source { <-3,5,3> color Blue fade_power 0.3 }
light_source { <-3,5,-3> color Yellow fade_power 0.3 }
light_source { <3,5,-3> color Green fade_power 0.3 }

                          
/* Caixa Mística do Fogo */                          
#declare caixa_vermelha = 
    box{
        <1,-1,10>,<6,4,15>
        texture{
            waves
            texture_map {
                [ 0.0 pigment { color rgb <0.8,0.1,0.2> } ]
                [ 0.4 pigment { color rgb <0.9,0.6,0.5> } ]
                [ 0.6 pigment { color rgb <0.9,0.2,0.4> } ]
                [ 1.0 pigment { color rgb <0.9,0.6,0.6> } ]
            }
        }
        translate <-3.5,-1.5,-12.5>
        scale 0.5
    }


/* Base da construção na forma de semitoro */
#declare pe =
    intersection{
        torus{
            6,0.7
            translate<0,0.7,0> 
        }
        box{
            <6.75,-1,6.75>,<-6.75,1,-6.75>
        }
        pigment{ color rgbt <0.68,0.83,0.9,.56>}
        interior {ior 1.6}
    }
                                             
/* Cúpula da construção na forma de semiesfera */                                              
#declare cabeca = 
    intersection{
        sphere{
            <0,-2.4,0>, 6.8
        }
        box{
            <5.7,0.4,5.7>,<-5.7,10,-5.7>
        }    
        pigment{ color rgbt <0.68,0.83,0.9,.56>}
        interior {ior 1.6}
    }

/* Chão com efeito de granito incandescente e fonte de luz */
#declare chao = 
    cylinder{
        <0,-0.1,0>,<0,0,0>,6
        texture{ 
            granite
            texture_map {
                [ 0.0 pigment { color rgb <0.4,0.3,0.7> } ]
                [ 0.4 pigment { color rgb <0.6,0.4,0.4> } ]
                [ 0.6 pigment { color rgb <0.7,0.6,0.4> } ]
                [ 1.0 pigment { color rgb <0.3,0.4,0.6> } ]
            }
        }
    }

union{
    plane{
        y, 0
        pigment{ color rgb <0.36, 0.62, 0.38> }
    }
    plane{
        z, 500
        pigment{ color rgb <0.4, 0.4, 1> }
    }
    object {pe}
    object {caixa_vermelha}
    object {chao}
    object {cabeca}
    light_source { <0,0.5,0> color White looks_like {chao}}
}