// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2000-09-21 20:06:05 by ra002388

//#include "skies.inc"

background{ color rgb < 0.00, 0.75, 0.85 > }

light_source {
  < 30.00, 100.00, 30.00 >
  color rgb < 1.00, 1.00, 1.00 >
}

sky_sphere {

    pigment {
				color rgb <0.4,0.9,1>
    }

    pigment {

      bozo

      turbulence 0.65

      octaves 6

      omega 0.7

      lambda 2

      color_map {

          [0.0 0.1 color rgb <1, 1, 1>

                   color rgb <0.9, 0.9, 0.9>]

          [0.1 0.5 color rgb <0.9, 0.9, 0.9>

                   color rgbt <1, 1, 1, 1>]

          [0.5 1.0 color rgbt <1, 1, 1, 1>

                   color rgbt <1, 1, 1, 1>]

      }

      scale <0.2, 0.5, 0.2>

    }

    rotate -135*x

  }




camera {
  location  28 * <  1, 0, 2 > + 28 * y
  right     < -1.20, 0.00, 0.00 >
  up        <  0.00, 0.00, 0.90 >
  sky       <  0.00, 1.00, 0.00 >
  look_at   <  0.00, 21.00, 0.00 >
}

#declare chao1 = <0,0.7,0.3>;
#declare chao2 = <0.4,0.8,0>;


#declare bluemetalreflection = <0.3,0.3,1.0>;
#declare bluemetal = texture {
	pigment { color bluemetalreflection }
	finish { diffuse 0.75 specular 0.5 roughness 0.005 ambient 0.1
		reflection bluemetalreflection
	}
}

#declare silvermetalreflection = <0.9,0.9,0.9>;
#declare silvermetal = texture {
	pigment { color silvermetalreflection }
	finish { diffuse 0.75 specular 0.5 roughness 0.005 ambient 0.1
		reflection silvermetalreflection
	}
}

#declare crystalcolor = <0.8,0.5,0.8>;
#declare crystal = texture {
	pigment { color crystalcolor filter 1.7}
	finish { diffuse 0.75 specular 0.5 roughness 0.005 ambient 0.1
		reflection 0.15*crystalcolor
	}
}

#declare tower = union {
	difference {
		cylinder {
			<13,0,13>,
			<13,36,13>,
			3
		}
		cylinder {
			<13,0,13>,
			<13,36,13>,
			2.4
		}
		texture { crystal }
		interior { ior 2.4 }
	}
	cone {
		<13,36,13>,4,
		<13,42,13>,0
		texture { bluemetal }
	}
	torus {
		4,1
		translate <13,32,13>
		texture { silvermetal }
	}
}

#declare ponte = intersection {
	difference {
		cylinder {
			<12,32,0>,
			<14,32,0>,
			8
		}
		cylinder {
			<11.5,32,0>,
			<14.5,32,0>,
			7
		}
	}
	box {
		<12,32,-8>,
		<14,40,8>
	}
	texture { silvermetal }
}

#declare cupula = difference {
	difference {
		sphere {
			<0,10,0>,
			15
		}
		sphere {
			<0,10,0>,
			14.5
		}
	}
	cylinder {
		<0,0,0>,
		<0,15,0>,
		8
	}
	texture { crystal }
}

#declare enfeite = torus {
	13,2
	translate <0,29,0>
	texture { silvermetal }
}

// Aqui está a cena, finalmente:

plane {y, 0
	pigment { checker color chao1, color chao2, scale 5 }
	finish { reflection 0.5 }
}

object { tower scale <1,1,1> }
object { tower scale <-1,1,1> }
object { tower scale <-1,1,-1> }
object { tower scale <1,1,-1> }
object { ponte rotate y*0}
object { ponte rotate y*90}
object { ponte rotate y*180}
object { ponte rotate y*270}
object { cupula }
object { enfeite }

// Adicione o sobretudo para transformar o dancarino num boneco de matrix lutador de kung fu
//  object { sobretudo translate < 0, 6, 0> }