// MC930A Nona Atividade de Laboratório utilizando POV-ray
// Autor: Mário Riudoms Sangenis  -  RA: 992198
// Last edited on 2003-05-31 11:24:17 by stolfi

#include "colors.inc"
#include "textures.inc"

background{ White }

#declare ctr = < 0.00, 0.00, 0.00 >;
camera {
  location ctr + 0.75 * < -8.00, 7.00, 25.00 >
  right 1.2*x   up 0.9*y  sky y
  look_at  ctr
} 

light_source { 100 * < 10.00, 20.00, 25.00 > color rgb 1.2*< 1.00, 1.00, 1.00 > } 
light_source { 100 * <-15.00, 30.00, 25.00 > color rgb 0.8*< 1.00, 1.00, 1.00 > } 
light_source { 100 * < 10.00, 50.00,  5.00 > color rgb 0.4*< 1.00, 1.00, 1.00 > } 

#declare furo =
 prism {
    cubic_spline
    0,
    1,
    6,
    < 3, -5>, 
    < 3,  5>, 
    <-5,  0>, 
    < 3, -5>, 
    < 3,  5>, 
    <-5,  0> 
    pigment { Gray30 }
  }


#declare corpo_bruto =
lathe {
  cubic_spline
  16,
  <1, 15>, <1, 10>, <1, 8>, <1.5, 7>, <1, 6>, <1, 3>, <2, 2>, <2.5, 1>, 
  <3.5, 0>, <4,-1>, <3.5, -2>, <2.5,-3>, <2, -4>, <1, -5>, <1, -7>, <0, -7>
  pigment {Tom_Wood}
 }


#declare corpo =
difference {
  object { corpo_bruto }
  box { <-4, 3, 2> <4, -3, 4> pigment {Tom_Wood}}
  sphere { <0, -0.7, 2>, 1.2 pigment {Gray30}}
  object { furo rotate <90,0,90> scale<.1,.1,5> translate<0,8,0>} 
  object { furo rotate <90,0,90> scale<.1,.1,5> translate<0,6.5,0>} 
  object { furo rotate <90,0,90> scale<.1,.1,5> translate<0,5,0>} 
}


#declare pe =
lathe {
  linear_spline
  5,
  <0,20>, <0,6>, <1,0>, <2,6>, <2,20>
  pigment {Gray30}
} 


#declare bucal =
lathe {
  linear_spline
  5,
  <0,20>, <0,6>, <1,0>, <2,6>, <2,20>
  texture {Silver_Metal}
} 


#declare barra =
union{
  box { <-2.2, 1.1, 2> <2.2, 1.3, 2.3> texture{ Silver_Metal }}
}


#declare corda =
union {
  cylinder { <-1.4, 1.3, 2.15> <-1.4, -2.3, 2.15> 0.1 pigment {Magenta}}
}


#declare plano =
  plane {
  y, -10.0
  pigment {checker color Gray80, color White }
}


// Aqui está a cena, finalmente:

union { 
  object { corpo }
  object { barra }
  object { barra translate <0,-3.6,0> }
  
  #declare pos = 0;
  #while (pos < 3) 
    object { corda translate <pos,0,0>}
    #declare pos = pos + .4;
  #end
  
  object { bucal scale <.5,.1,.5> rotate <180,0,0> translate <0,12,0>}
  object { pe scale <.5,.2,.5> translate <0,-10,0>}
  rotate <0,0,-90>
  rotate <-60,0,0>
}
object { plano }