// Arquivo de descricao de cena para POV-Ray referente a tarefa 08.
// Last edited on 2003-05-31 10:32:11 by stolfi
// Last edited on 2003-05-15 by Evandro.

#include "colors.inc"
#include "stones.inc"
#include "textures.inc"

background { color Blue }

#declare ctr = <3.00,  8.00, 0.00>;

camera {
  location ctr + 1.0 * <10.00, 15.00,  20.00>
  right   1.0*x  up 0.75*y
  look_at  ctr
}

light_source { <-50.00, 50.00, 50.00> color 1.0*White }
light_source { <  0.00, 50.00, 51.00> color 0.5*White }
light_source { <+50.00, 50.00, 52.00> color 0.7*White }


#declare piso =
  plane { <0,1,0>, -0.001 pigment { checker color Black, color White scale 3 } }


#declare topoInstrumento =
  prism {
    cubic_spline 0.00, 0.20, 6,
    <+5.00, +3.00>, < 0.00, -3.00>, <-5.00, +3.00>,
    <+5.00, +3.00>, < 0.00, -3.00>, <-5.00, +3.00>
    pigment {Brass}
  }

#declare baseInstrumento =
  prism {
    cubic_spline 0.00, 5.00, 6,
    <+5.00, +3.00>, < 0.00, -3.00>, <-5.00, +3.00>,
    <+5.00, +3.00>, < 0.00, -3.00>, <-5.00, +3.00>
    texture {Tan_Wood}
  }

#declare pernaInstrumento =
  cylinder { <0.00, 0.00, 0.00>, <0.00, 3.00, 0.00>, 1.00 pigment {DarkBrown} }

#declare atabaque =
  union {
    object { topoInstrumento translate <0.00, 8.00, 0.00> }
    object { baseInstrumento translate <0.00, 3.00, 0.00> }
    object { pernaInstrumento translate <+4.00, 0.00, +2.00> }
    object { pernaInstrumento translate <-4.00, 0.00, +2.00> }
    object { pernaInstrumento translate < 0.00, 0.00, -2.00> }
  }


#declare ponta =
  sphere { <0.00, 0.00, 0.00>, 0.60 texture {Silver_Metal} }

#declare haste =
  lathe {
    cubic_spline 8,
    <0.00, 0.00>, <1.00, 0.00>, <1.00,  1.00>, <2.00,  2.00>,
    <2.50, 4.00>, <0.80, 4.00>, <0.40, 12.00>, <0.00, 12.00>
    pigment {Gray50}
  }

#declare baqueta =
  union {
    object { ponta translate <0.00, 12.00, 0.00> }
    object { haste }
  }


union {
  object { piso }
  object { atabaque }
  object { baqueta rotate <-25,0,+25> translate <+12.00, 4.00, 0.00> }
  object { baqueta rotate <-25,0,-25> translate <-12.00, 4.00, 0.00> }
}