//Arquivo de descricao de cena para POV-Ray referente a tarefa 08.
//Last edited on 2003-05-15 by Evandro.

#include "colors.inc"
#include "stones.inc"
#include "textures.inc"

background { color Blue }

camera {
  location <0.00, 15.00,  35.00>
  right    <1.00,  0.00,   0.00>
  up       <0.00,  0.50,   0.00>
  look_at  <0.00,  0.00, -30.00>
}

light_source { <50.00, 50.00, 50.00> color White }
light_source { <50.00, 50.00, 51.00> color White }
light_source { <50.00, 50.00, 52.00> color White }


#declare piso =
  plane { <0,1,0>, -0.001 pigment { checker color Black, color White } }


#declare topoInstrumento =
  prism {
    cubic_spline 0.00, 0.20, 6,
    <+5.00, +3.00>, < 0.00, -3.00>, <-5.00, +3.00>,
    <+5.00, +3.00>, < 0.00, -3.00>, <-5.00, +3.00>
    pigment {Brass}
  }

#declare baseInstrumento =
  prism {
    cubic_spline 0.00, 5.00, 6,
    <+5.00, +3.00>, < 0.00, -3.00>, <-5.00, +3.00>,
    <+5.00, +3.00>, < 0.00, -3.00>, <-5.00, +3.00>
    texture {Tan_Wood}
  }

#declare pernaInstrumento =
  cylinder { <0.00, 0.00, 0.00>, <0.00, 3.00, 0.00>, 1.00 pigment {DarkBrown} }

#declare atabaque =
  union {
    object { topoInstrumento translate <0.00, 8.00, 0.00> }
    object { baseInstrumento translate <0.00, 3.00, 0.00> }
    object { pernaInstrumento translate <+4.00, 0.00, +2.00> }
    object { pernaInstrumento translate <-4.00, 0.00, +2.00> }
    object { pernaInstrumento translate < 0.00, 0.00, -2.00> }
  }


#declare ponta =
  sphere { <0.00, 0.00, 0.00>, 0.60 texture {Silver_Metal} }

#declare haste =
  lathe {
    cubic_spline 8,
    <0.00, 0.00>, <1.00, 0.00>, <1.00,  1.00>, <2.00,  2.00>,
    <2.50, 4.00>, <0.80, 4.00>, <0.40, 12.00>, <0.00, 12.00>
    pigment {Gray20}
  }

#declare baqueta =
  union {
    object { ponta translate <0.00, 12.00, 0.00> }
    object { haste }
  }


union {
  object { piso }
  object { atabaque }
  object { baqueta rotate <-25,0,+25> translate <+12.00, 4.00, 0.00> }
  object { baqueta rotate <-25,0,-25> translate <-12.00, 4.00, 0.00> }
}