// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2003-04-12 05:22:47 by stolfi

#include "colors.inc"

background{White}

#declare ctr = <-1.2, -2, 2.0>;
// #declare cam = <1,2,6>;
#declare cam = <-5,1.3,2>;

camera {
  // location 0.5*<35,0,12>
  // location ctr + <0,18,-0,1>
  // location ctr + 2.8*<-5,3,-3>
  location ctr + 2.6*cam
  right -0.60*x up 0.80*y
  sky y
  look_at ctr
}

light_source { ctr + 10*<12, 20, -4> color 0.5*White }

light_source { ctr + 10*<-12, 20, -4> color 0.5*White }

// light_source { ctr + 10*<-5,2,1> color 0.5*White }

light_source { ctr + 10*(cam + <0.6,0,-2.0>) color 0.6*White }


#declare cor_espelho = < 0.80, 0.80, 0.20 >;

#declare tx_espelho =
  texture {
    pigment { rgb cor_espelho }
    finish {
      ambient 0.05 diffuse 0.05
      reflection cor_espelho
      specular 0.20 roughness 0.05
    }
  }

#declare cor_cristal = < 0.20, 0.20, 0.70>;

#declare tx_cristal =
  texture {
    finish {
      ambient 0.1 diffuse 0.1
      reflection 0.25
      specular 1.0 roughness 0.02
    }
    pigment { color cor_cristal filter 1 }
  }


#declare piso =
  plane { <0, 1, 0>, -5 pigment {White} normal {granite 2 scale 5} }

#declare cano_da_arma =
  difference {
    cylinder { <0, 0, 0>, <-3, 0, 5>, 1.0 texture { tx_espelho } }
    cylinder { <0, 0, 0>, <-6, 0, 10>, 0.5 pigment {Black} }
  }

#declare tambor =
  torus { 1.5, 0.50 rotate <90, 0, 0> texture {tx_espelho} }

#declare manopla =
  cone { <0, 0, 0>, 1, <2, -2, -2>, 1.50  texture {tx_espelho} }

#declare haste =
  blob {
    threshold 0.75
    cylinder { <-2.6, 0, 4>, <-3.2, -3, 3.75>, 0.75 1 }
    cylinder { <-1, -3.5, 4>, <-5, -2.5, 3>, 0.75 1 }
    texture { tx_cristal }
    finish { phong 1 }
  }

#declare porta_copo =
  difference {
    cylinder { <0, 0.0, 0>, <0, 1, 0>, 1.0 }
    cylinder { <0, 0.5, 0>, <0, 2, 0>, 0.5 }
    rotate <10, 0, -10>
    texture { tx_cristal }
    interior { ior 2.0 }
  }


union {
  object { piso }
  object { cano_da_arma }
  object { tambor rotate <0, -40, 0> }
  object { manopla }
  object { haste }
  object { porta_copo translate <-1, -3.5, 4> }
  object { porta_copo translate <-5, -2.5, 3> }
}