background { color rgb <0,0,0> }

light_source {
  < 200, 200, -200 >
  color rgb < 1, 1, 1 >
} 

camera {
  location <-14, 0, -20>
  look_at  < 0, 0, 0 >
  sky <0,1,0>
} 


plane { y, -10
  texture {
    pigment {
      checker
      color rgb <0,0,0>
      color rgb <.9,.9,.9>
    }
  }
}


#declare abdomem =
sphere { 
  <0,0,0>, 6
}

#declare cabeca =
sphere {
  <0,8,0>, 2
}

#declare bico =
cone {
  <0,7,-1.5>, .7,
  <0,7,-3.9>, 0
}

/* oculos (visor futurista) */
#declare visor =
box {
  <-.5,8.5,-3.3>,
  <.5,9.3,-1.5>
}

#declare perna_esquerda =
cylinder {
  <-3.1,-3.1,0>, <-5,-9,0>, 1
}

#declare asa_esquerda =
box {
  <-10, -.5, -1.8>, <-5, .5, 1.8>
}

/* quanto maior a espessura (ou quanto menor o rgb), mais
   rarefeito fica o gas */
#declare espessura = 12;
#declare amarelado1 = color rgb (1.0/espessura)*<1, 1, .1>;
#declare amarelado2 = color rgb .2*<1, 1, .1>;
#declare esverdeado = color rgb .5*<.4,1,.4>;
#declare azulado = color rgb .3*<.5,.5,1>;
#declare avermelhado1 = color rgb .5*<1,.5,.5>;
#declare avermelhado2 = color rgb .35*<1,.5,.5>;

merge {

object { cabeca
  hollow
  pigment { color rgbt <1,1,1,1> } /* transparente */
  interior {
     media { emission color amarelado2 }
  }
}

object { abdomem
  hollow
  pigment { color rgbt <1,1,1,1> } /* transparente */
  interior {
     media { emission color amarelado1 }
  }
}

union {
  object { asa_esquerda }
  object { asa_esquerda
    scale <-1,1,1>
  }
  hollow
  pigment { color rgbt <1,1,1,1> } /* transparente */
  interior {
     media { emission color avermelhado2 }
  }
}

union {
  object { perna_esquerda }
  object { perna_esquerda
    scale <-1,1,1>
  }
  hollow
  pigment { color rgbt <1,1,1,1> } /* transparente */
  interior {
     media { emission color avermelhado1 }
  }
}

object { visor
  hollow
  pigment { color rgbt <1,1,1,1> } /* transparente */
  interior {
     media { emission color esverdeado }
  }
}

object { bico
  hollow
  pigment { color rgbt <1,1,1,1> } /* transparente */
  interior {
     media { emission color azulado }
  }
}

} /* merge */


fog {
  distance 40
  color rgb <.3, .3, .3>
}