// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2000-09-21 20:06:05 by stolfi

background{ color rgb < 0.00, 0.0, 0.02 > }

#declare posicao = <50,50,50>;
#declare alvo = <0,0,0>;
#declare distancia = vlength(posicao-alvo);
#declare abertura = degrees(40/distancia);

light_source {
  posicao
  color rgb < 1.0, 1.0, 1.0 >
  spotlight
  point_at alvo
  radius 0.8*abertura falloff 1.2*abertura
  fade_distance distancia
  fade_power 2
} 

fog {
   distance 12
   color rgbf <.5,.5,.5,1.0>
   fog_type 2
   fog_offset 2
   fog_alt 1
   rotate x*90
}

camera {
  location  < 50.00, 12.00, 40.00 >
  //right     <  1.00, 0.00, 0.00 >
  //up        <  0.00, 1.00, 0.00 >
  sky       <  0.00, 0.00, 1.00 >
  look_at   <  0.00, 0.00, 12.00 >
} 


#declare corpo =
   union {
     sphere {
        <0,0,0>,7
     }
     cylinder {
        <4,0,0>,
        <4,0,17>, 3
     }
     sphere {
        <4,0,17>,3
     }
   }
#declare bico =
   cone {
      <4,0,13>,2,
      <10,0,13>,0
   }

#declare olho =
   sphere {
      <7,0,16>,.5
   }

#declare perna =
   cylinder {
      <0,0,-4>
      <0,0,-12>,.2
   }

union {
   object {
      corpo
      texture { 
                pigment { color rgb <1,1,1> }
                finish {reflection .5 metallic}
               }
   }
   object {
      bico
      texture { 
                pigment { color rgb <1,1,0> }
                finish {metallic reflection .5}
               }
   }
   object {
      olho
      translate <0,-1,0>
      hollow
      pigment { color rgbt <1,1,1,1>  }
      interior { media { emission color rgb <10,0,0> } }
      
   }

   object {
      olho
      translate <0,1,0>
      hollow
      pigment { color rgbt <1,1,1,1>  }
      interior { media { emission color rgb <10,0,0> } }
   }

   object {
      perna
      translate <0,-4,0>
      texture { 
                pigment { color rgb <.5,.2,0> }
               }
      
   }

   object {
      perna
      translate <0,4,0>
      texture { 
                pigment { color rgb <.5,.2,0> }
               }
      
   }

   translate <0,0,12>
}

torus {
   3,.2
   hollow
   pigment { color rgbt <1,1,1,1>  }
   interior { media {emission color rgb <10,10,0> }}
   rotate x*90
   translate <4,0,33>
}

plane {
   <0,0,1>,0
   texture { pigment {brick} }
}