#include "colors.inc"
#include "textures.inc"

camera {
    location < -2, 1, -50 >
    look_at 0
    angle 15
}

background { color SkyBlue }

#declare posicao = < 0.00 , 50.00 , -50.00>;

#declare alvo = < 0.00, 0.00, 0.00 >;

#declare distancia = vlength(posicao - alvo);

#declare raio = 3.50;

#declare abertura = degrees(raio/distancia);

#declare espessura = 6 ;

#declare amarelado = color rgb (1.0/espessura)*<1,1,0>;


light_source {
  posicao
  color rgb <1,1,1>
  spotlight
  point_at alvo
  radius 0.8*abertura falloff 1.2*abertura
  fade_distance distancia
  fade_power 2
}

#declare chao =
  plane {y,-5
    texture {
      pigment {
        color < 1.00, 0.50, 0.00>
      }
      finish {
        ambient .25
        diffuse .6
        crand .5
      }
      normal {
        ripples .35
        turbulence .25
        frequency 5
      }
      scale 10
      translate 50*x
    }
  }

#declare corpo =
  sphere {
    < 0.00, 0.00, 0.00 >
    2
    hollow
    pigment { color rgbt < 1, 1, 1, 1 > }
    interior {
      media { scattering { 1, color amarelado } }
    }
  }

#declare olho =
  sphere {
    < 0.00, 0.00, 0.00 >
    0.10
    pigment { Yellow }
  }
#declare pescoco =
  cylinder {
    < 0.00, 0.00, 0.00 >
    < 0.00, 1.50, 0.00 >
    0.25
    hollow
    pigment { color rgbt < 1, 1, 1, 1 > }
    interior {
      media { scattering { 1, color amarelado } }
    }
  }

#declare bico =
  cone {
    < 0.00, 0.00, 0.00 > 0.30
    < -0.80, 0.00, 0.00 > 0.00
    hollow
    texture { Orange_Glass }
  }

#declare perna =
  cylinder {
    < 0.00, 0.00, 0.00 >
    < 0.00, 2.00, 0.00 >
    0.175
    hollow
    texture { Orange_Glass }
  }

#declare brinco =
    torus { .3, .04
      hollow
      pigment { Blue }
    }

merge {
  object {
    corpo
    scale < 1.00, 0.75, 0.75 >

  }
  object {
    pescoco
    translate < -1.00, 1.00, 0.00 >
    rotate < 0.00, 0.00, 30.00 >
  }
  object {
    corpo
    scale < 0.40, 0.30, 0.30 >
    translate < -2.50, 1.50, 0.00 >
  }
  object {
    bico
    translate < -3.00, 1.50, 0.00 >
  }
  object {
    perna
    translate < 0.00, -3.00, -0.80 >
    rotate < 20.00, 0.00, -20.00 >
  }
  object {
    perna
    translate < 0.00, -3.00, 0.80 >
    rotate < -20.00, 0.00, 20.00 >
  }
  object {
    brinco
      rotate < -90.00, 50.00, 0.00 >
      translate < -3.40, 1.18, -0.09 >
   }
}

object { chao }

fog {
  distance 70
  color rgb <0.4, 0.4, 0.4>
  fog_type 2
  fog_offset 25
  fog_alt 1
  turbulence 0.1
  turb_depth 0.2
}