//Eduardo Hideki Tanaka  RA: 970563
//   Sexto Exercicio - MC930


background{ color rgb < 0.22, 0.20, 0.82 > }

light_source {
  < 21.00, 9.00, -7.00 >  //-1 9 -7
  color rgb < 1.20, 1.20, 1.20 >
} 

camera {
  location  <  26.00, 10.00, -7.00 >
  look_at   <  10.00, 1.00, 8.00 >
} 

//plano que servira de base
plane { y, 0
  texture {
    pigment {
      checker
      color rgb <0.2, 0.1, 0.1>
      color rgb <1, 1, 1>
    }
  }
}

//plano que da a impressao do ceu
plane { y, 500
  texture {
    pigment { color rgb <0.22, 0.3, 0.82> }
    finish { ambient 1 diffuse 0}
  }
  texture {
    pigment {
      bozo
      turbulence .5
      color_map {
        [0 color rgb <1, 1, 1>]
        [1 color rgb <1, 1, 1> filter 1]
      }
    }
    finish { ambient 1 diffuse 0 }
    scale <1000, 250, 250>
    rotate <5, 45, 0>
    }
}

#declare tinta_verde = 
  texture {
    pigment { color rgb < 0.10, 1.00, 0.25 > }
    normal { bumps 0.08 scale 0.1 }
    finish { diffuse 0.9 specular 0.5 ambient 0.1 phong 1 }
  }

#declare tinta_amarela = 
  texture {
    pigment { color rgb < 1.00, 1.00, 0.10 > }
    finish { specular 0.4 reflection .65 phong 1 }
  }

#declare tinta_vermelha =
  texture {
    pigment { color rgb < 0.80, 0.15, 0.10 > }
    normal { waves 1 scale 0.1 }
    finish { diffuse 0.9 ambient 0.1 phong 1 }
  }

#declare tinta_vermelha_sem_textura = 
  texture {
    pigment { color rgb < 0.80, 0.15, 0.10 > }
    finish { diffuse 0.9 ambient 0.1 phong 1 }
  }

#declare tinta_marrom = 
  texture {
    pigment {
      wood
      color_map {
        [0.0 color rgb <1.00, 0.80, 0.50 >]
        [0.9 color rgb <1.00, 0.95, 0.55>]
        [1.0 color rgb <1.00, 0.95, 0.7>]
      }
      turbulence 0.05
      scale <0.2, 0.3, 1> 
    }
    finish { diffuse 0.9 ambient 0.1 }
  }

#declare cilindro = 
  cylinder {
    <4.00, 1.00, 4.00>,
    <4.00, 5.30, 4.00>,
    3.00
    texture { tinta_vermelha }
  }

#declare furoC =
  cylinder {
    <4.00, 1.10, 4.00>,
    <4.00, 5.40, 4.00>,
    2.70
    texture { tinta_vermelha_sem_textura }
  }

#declare caixa1 = 
  box {
    <9.00, 1.00, 1.00>,
    <14.00, 2.00, 14.00>
    texture { tinta_verde }
  }

#declare caixa2 = 
  box {
    <11.00, 2.00, 1.00>,
    <12.00, 3.00, 14.00>
    texture { tinta_verde }
  }

#declare caixa3 = 
  box {
   <16.00, 1.00, 5.00>,
   <22.00, 1.75, 11.00>
   texture { tinta_amarela }
  }

#declare esfera = 
  sphere {
    <4.00, 3.00, 11.00>,
    3.00
    texture { tinta_vermelha }
  }

#declare furoE = 
  sphere {
    <4.00, 3.00, 11.00>,
    2.80
    texture { tinta_vermelha_sem_textura }
  }

#declare corteE = 
  box {
    <1.00, 1.00, 8.00>,
    <7.00, 3.00, 14.00>
  }

#declare tampaB = 
  box {
    <0.00, 0.00, 0.00>,
    <23.00, 1.00, 15.00>
    texture { tinta_marrom }
  }

//a cena final esta aqui
union{
  merge {
    object { caixa1 }
    object { caixa2 }
  }
  difference {
    object { cilindro }
    object { furoC }
  }
  intersection {
    difference {
      object { esfera }
      object { furoE } 
    }
    object { corteE }
  }
  object { caixa3 }
  object { tampaB }
}